net-print/foo2zjs/foo2zjs-20050319.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/foo2zjs/foo2zjs-20050319.ebuild,v 1.1.1.1 2005/11/30 09:48:18 chriswhite Exp $

inherit eutils flag-o-matic

DESCRIPTION="Support for printing to ZjStream-based printers"
HOMEPAGE="http://foo2zjs.rkkda.com/"
SRC_URI="mirror://gentoo/${P}.tar.gz
		ftp://ftp.minolta-qms.com/pub/crc/out_going/win/m23dlicc.exe
		ftp://ftp.minolta-qms.com/pub/crc/out_going/win2000/m22dlicc.exe
		ftp://ftp.minolta-qms.com/pub/crc/out_going/windows/cpplxp.exe"
RESTRICT="nomirror"
LICENSE="GPL-2"
SLOT="0"
IUSE="cups foomaticdb usb"
DEPEND="cups? ( net-print/cups )
	foomaticdb? ( net-print/foomatic )
	usb? ( sys-apps/hotplug )"
KEYWORDS="x86 ~amd64"
S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${P}.tar.gz

	epatch ${FILESDIR}/${PN}-Makefile.patch
	epatch ${FILESDIR}/hp-printer-udev.patch

	# link getweb files in ${S} to get unpacked
	for i in ${A}
	do
		ln -s ${DISTDIR}/${i} ${S}
	done

	cd ${S}
}

src_compile() {
	emake getweb || die "Failed building getweb script"

	# remove wget as we got the firmware with portage
	sed -si "s/.*wget.*//" getweb
	sed -si "s/error \"Couldn't dow.*//" getweb
	# unpack files
	./getweb all

	emake || die "emake failed"
}

src_install() {
	useq foomaticdb && dodir /usr/share/foomatic/db/source

	useq cups && dodir /usr/share/cups/model

	make DESTDIR=${D} install \
		|| die "make install failed"

	if useq usb; then
		make DESTDIR=${D} install-hotplug \
			|| die "make install-hotplug failed"
	fi
}