From b089b88af4f627a8e209c8c23d189cc1957ee62a Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Wed, 15 Jun 2022 10:42:51 +0200
Subject: media-gfx/jpeg2ps: Update SRC_URI
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Bump ebuild to EAPI 8. Update LICENSE and RESTRICT.

Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild | 46 ---------------------------------
 media-gfx/jpeg2ps/jpeg2ps-1.9-r3.ebuild | 43 ++++++++++++++++++++++++++++++
 2 files changed, 43 insertions(+), 46 deletions(-)
 delete mode 100644 media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild
 create mode 100644 media-gfx/jpeg2ps/jpeg2ps-1.9-r3.ebuild

(limited to 'media-gfx')

diff --git a/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild b/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild
deleted file mode 100644
index 9a25a5e30b7d..000000000000
--- a/media-gfx/jpeg2ps/jpeg2ps-1.9-r2.ebuild
+++ /dev/null
@@ -1,46 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit toolchain-funcs readme.gentoo-r1
-
-DESCRIPTION="Convert JPEG images to Postscript using a wrapper"
-HOMEPAGE="https://web.archive.org/web/20131003144811/http://www.pdflib.com/download/free-software/jpeg2ps/"
-SRC_URI="https://web.archive.org/web/20131003165952/http://www.pdflib.com/fileadmin/pdflib/products/more/${PN}/${P}.tar.gz"
-
-LICENSE="free-noncomm"
-SLOT="0"
-KEYWORDS="amd64 ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="metric"
-
-PATCHES=("${FILESDIR}"/${P}-include.diff)
-
-src_compile() {
-	emake \
-		CC="$(tc-getCC)" \
-		LD="$(tc-getCC)" \
-		CFLAGS="-c ${CFLAGS} $(usex metric "-DA4" "")" \
-		LDFLAGS="${LDFLAGS}"
-}
-
-src_install() {
-	dobin jpeg2ps
-	doman jpeg2ps.1
-	dodoc jpeg2ps.txt
-
-	if use metric; then
-		DOC_CONTENTS="By default, this installation of jpeg2ps will generate
-			A4 size output.  You can force letter output with
-			\n\tjpeg2ps -p letter file.jpg > file.ps"
-	else
-		DOC_CONTENTS="By default, this installation of jpeg2ps will generate
-			letter size output.  You can force A4 output with
-			\n\tjpeg2ps -p a4 file.jpg > file.ps"
-	fi
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-}
diff --git a/media-gfx/jpeg2ps/jpeg2ps-1.9-r3.ebuild b/media-gfx/jpeg2ps/jpeg2ps-1.9-r3.ebuild
new file mode 100644
index 000000000000..430fe4f17edc
--- /dev/null
+++ b/media-gfx/jpeg2ps/jpeg2ps-1.9-r3.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs readme.gentoo-r1
+
+DESCRIPTION="Convert JPEG images to Postscript using a wrapper"
+HOMEPAGE="https://web.archive.org/web/20131003144811/http://www.pdflib.com/download/free-software/jpeg2ps/"
+SRC_URI="https://distfiles.macports.org/${PN}/${P}.tar.gz"
+
+LICENSE="jpeg2ps"
+SLOT="0"
+KEYWORDS="amd64 ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="metric"
+RESTRICT="mirror"
+
+PATCHES=("${FILESDIR}"/${P}-include.diff)
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		LD="$(tc-getCC)" \
+		CFLAGS="-c ${CFLAGS} $(usev metric -DA4)" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin jpeg2ps
+	doman jpeg2ps.1
+	dodoc jpeg2ps.txt
+
+	local size1=letter size2=A4
+	use metric && size1=A4 size2=letter
+	DOC_CONTENTS="By default, this installation of jpeg2ps will generate
+		${size1} size output. You can force ${size2} output with
+		\n\tjpeg2ps -p ${size2} file.jpg > file.ps"
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad