From 053f5a7de074c3b9bb7576c5e25b0732d7c4d062 Mon Sep 17 00:00:00 2001
From: Sven Wegener <swegener@gentoo.org>
Date: Fri, 8 Jul 2022 17:47:09 +0200
Subject: net-dns/pdns-recursor: Version bump to 4.7.1

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Sven Wegener <swegener@gentoo.org>
---
 net-dns/pdns-recursor/Manifest                   |  1 +
 net-dns/pdns-recursor/pdns-recursor-4.7.1.ebuild | 88 ++++++++++++++++++++++++
 2 files changed, 89 insertions(+)
 create mode 100644 net-dns/pdns-recursor/pdns-recursor-4.7.1.ebuild

(limited to 'net-dns/pdns-recursor')

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index b2acf40866c2..8f1f81fe706d 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,2 +1,3 @@
 DIST pdns-recursor-4.6.2.tar.bz2 1552587 BLAKE2B 3e7fe59ebe9d776c012304fc1bf6ed723c1c15df0aaedcaa8ac538741e81c5b6ebac2528e763e1395a0ea383904e4a902319509580938caae85b3aef947cfc3d SHA512 20779a065720162f0a6223a4d92deeef7911892bb8aa1929f9c6a8a6ccd2f8756e7bd35c877dbf945bb7627a2a7d40626d02f0008c2e8a602b424d36c110fddc
 DIST pdns-recursor-4.7.0.tar.bz2 1596954 BLAKE2B d2fb35caef19ee21ff495deb19939659940f245b44f6ff38977f328af9821862b939c48b5052b42ae83ae09647bab53094816b6dbe784737ef4c53ba02add855 SHA512 095272311623684a5a465ae48bd97b86ffe27d4092dea5dceee915ebb071ffb976eeb4055d560d834a3fafab0b15808137e384f28b7cec24719b78ac024e48c2
+DIST pdns-recursor-4.7.1.tar.bz2 1597536 BLAKE2B fc5d7ee80823ad55a986a9317d4be5be7d1ec1d1b993a5bb1bf0c138a901d4f81d4ebcef5e9774cd5de88c9f650053be26dc01dfd31b989dae25d53d12b87bad SHA512 7769c4c082bbf52b0e13adbe9c1c7272a638c0b2b11e1d76794cea66dfe8dc83b07989fa16707a7cc682e8c366ef4c1d37a614ad2841af33ccb9adec6270e07f
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.7.1.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.7.1.ebuild
new file mode 100644
index 000000000000..fe258d909f08
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.7.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	elibc_glibc? (
+		arm? ( >=sys-libs/glibc-2.34 )
+		x86? ( >=sys-libs/glibc-2.34 )
+	)
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:=[context]"
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+	append-lfs-flags
+	append-cppflags -D_TIME_BITS=64
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}
-- 
cgit v1.2.3-65-gdbad