From 30f46038c83a6aed410f146cb1ddac78201d9346 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Wed, 22 Jul 2020 19:05:39 -0700
Subject: net-libs/libnftnl: Add 9999 ebuild

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 net-libs/libnftnl/libnftnl-9999.ebuild | 60 ++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-libs/libnftnl/libnftnl-9999.ebuild

(limited to 'net-libs/libnftnl')

diff --git a/net-libs/libnftnl/libnftnl-9999.ebuild b/net-libs/libnftnl/libnftnl-9999.ebuild
new file mode 100644
index 000000000000..ee2ad5f135b6
--- /dev/null
+++ b/net-libs/libnftnl/libnftnl-9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info toolchain-funcs usr-ldscript
+
+DESCRIPTION="Netlink API to the in-kernel nf_tables subsystem"
+HOMEPAGE="https://netfilter.org/projects/nftables/"
+
+if [[ ${PV} =~ ^[9]{4,}$ ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.netfilter.org/${PN}"
+else
+	SRC_URI="https://netfilter.org/projects/${PN}/files/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/11" # libnftnl.so version
+IUSE="examples static-libs test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=net-libs/libmnl-1.0.4"
+BDEPEND="virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	if kernel_is ge 3 13; then
+		CONFIG_CHECK="~NF_TABLES"
+		linux-info_pkg_setup
+	else
+		eerror "This package requires kernel version 3.13 or newer to work properly."
+	fi
+}
+
+src_prepare() {
+	default
+	[[ ${PV} =~ ^[9]{4,}$ ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	gen_usr_ldscript -a nftnl
+	find "${ED}" -type f -name '*.la' -delete || die
+
+	if use examples; then
+		find examples/ -name 'Makefile*' -delete || die "Could not rm examples"
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.2.3-65-gdbad