From d75d22a993664108aadd3ab32770feb818f558d3 Mon Sep 17 00:00:00 2001
From: Craig Andrews <candrews@gentoo.org>
Date: Mon, 27 Jun 2022 10:34:32 -0400
Subject: net-misc/mptcpd: delete .la libtool archives

Closes: https://bugs.gentoo.org/849278
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Craig Andrews <candrews@gentoo.org>
---
 net-misc/mptcpd/mptcpd-0.10-r1.ebuild | 74 +++++++++++++++++++++++++++++++++++
 net-misc/mptcpd/mptcpd-9999.ebuild    | 10 +++--
 2 files changed, 80 insertions(+), 4 deletions(-)
 create mode 100644 net-misc/mptcpd/mptcpd-0.10-r1.ebuild

(limited to 'net-misc/mptcpd')

diff --git a/net-misc/mptcpd/mptcpd-0.10-r1.ebuild b/net-misc/mptcpd/mptcpd-0.10-r1.ebuild
new file mode 100644
index 000000000000..2ee9b4505be0
--- /dev/null
+++ b/net-misc/mptcpd/mptcpd-0.10-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools linux-info systemd
+
+DESCRIPTION="Daemon that performs multipath TCP path management related operations."
+HOMEPAGE="https://github.com/intel/mptcpd/"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="debug doc"
+
+RDEPEND="
+	>=dev-libs/ell-0.45.0
+	elibc_musl? ( sys-libs/argp-standalone )
+	"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.6
+	"
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		app-text/pandoc
+	)
+	virtual/pkgconfig
+	"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/mptcpd.git"
+else
+	SRC_URI="https://github.com/intel/mptcpd/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+CONFIG_CHECK="MPTCP"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9-no-werror.patch
+)
+
+src_prepare() {
+	default
+
+	# For Werror patch
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-kernel=upstream
+		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+		$(use_enable debug)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+	use doc && emake doxygen-doc
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/net-misc/mptcpd/mptcpd-9999.ebuild b/net-misc/mptcpd/mptcpd-9999.ebuild
index f678fe599d7a..2ee9b4505be0 100644
--- a/net-misc/mptcpd/mptcpd-9999.ebuild
+++ b/net-misc/mptcpd/mptcpd-9999.ebuild
@@ -13,7 +13,7 @@ SLOT="0/${PV}"
 IUSE="debug doc"
 
 RDEPEND="
-	>=dev-libs/ell-0.30.0
+	>=dev-libs/ell-0.45.0
 	elibc_musl? ( sys-libs/argp-standalone )
 	"
 DEPEND="
@@ -27,9 +27,6 @@ BDEPEND="
 	)
 	virtual/pkgconfig
 	"
-PATCHES=(
-	"${FILESDIR}/${P}-loopback-monitoring.patch"
-)
 
 if [[ ${PV} == 9999* ]]; then
 	inherit git-r3
@@ -70,3 +67,8 @@ src_compile() {
 src_test() {
 	emake check
 }
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad