# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/musca/musca-0.9.24_p20100226-r2.ebuild,v 1.1 2011/10/06 20:31:51 jer Exp $

EAPI="4"

inherit eutils savedconfig toolchain-funcs

DESCRIPTION="A simple dynamic window manager for X, with features nicked from
ratpoison and dwm"
HOMEPAGE="http://aerosuidae.net/musca.html"
SRC_URI="mirror://gentoo/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="apis xlisten"

COMMON="x11-libs/libX11"
DEPEND="${COMMON}
	sys-apps/sed"
RDEPEND="
	${COMMON}
	>=x11-misc/dmenu-4.4
	apis? ( x11-misc/xbindkeys )
"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-0.9.24-make.patch \
		"${FILESDIR}"/${PN}-0.9.24_p20100226-dmenu-4.4.patch

	local i
	for i in apis xlisten; do
		if ! use ${i}; then
			sed -e "s|${i}||g" -i Makefile || die
		fi
	done

	restore_config config.h
	tc-export CC
}

src_install() {
	dobin musca

	local i
	for i in xlisten apis; do
		if use ${i}; then
			dobin ${i}
		fi
	done
	doman musca.1

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/${PN}.xsession musca

	save_config config.h
}