From 502ac0fef8b765c2b12dfd0d938cce0324f8b4e5 Mon Sep 17 00:00:00 2001
From: Takuya Wakazono <pastalian46@gmail.com>
Date: Fri, 2 Aug 2024 21:49:15 +0900
Subject: app-text/komikku: add 1.52.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>
---
 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.52.0.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)
 create mode 100644 app-text/komikku/komikku-1.52.0.ebuild

(limited to 'app-text')

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 4466e1215..920026724 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.51.1.tar.gz 4937165 BLAKE2B 7819b176a6f6db2625a5cbfb7a487f58b79b43dab5e1bb24bdb95c7cd809ad1e5310b63cb21205125745d7d5286ebbdc35ecb9be80f59d3b5015b941e79fe7c1 SHA512 be91cf6b48f10063c027d6079a9addde87dea436215fc786cba9eb8e59aa11788485f2a3a1b5910a036e3b428d181892d81fa4c718ce79699a6a60b99d320778
+DIST komikku-1.52.0.tar.gz 4938411 BLAKE2B eed97fcfc145bc4c20ef642dab01eb20677c57c522c92961d63b4b5603aa37266075c7dae3dc9626ea87b151f30c0b9d5218b1b02ae4446048291a0b8bca43d1 SHA512 bc2f9020326e45e964e55f670dc5f9fc60e6cca67660a5535e10e997da7117911244aed11fc2a952fc46be99bdd3eb3f091265173ebf7eca0002a5350893ef0e
diff --git a/app-text/komikku/komikku-1.52.0.ebuild b/app-text/komikku/komikku-1.52.0.ebuild
new file mode 100644
index 000000000..7af66f6f1
--- /dev/null
+++ b/app-text/komikku/komikku-1.52.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.5:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}
-- 
cgit v1.2.3-65-gdbad