From 87a1c01cf6221a66cdaa2614a7d32e3a0536209b Mon Sep 17 00:00:00 2001
From: Sven Wegener <swegener@gentoo.org>
Date: Thu, 22 Oct 2020 13:19:02 +0200
Subject: net-dns/pdns-recursor: Version bump to 4.4.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Sven Wegener <swegener@gentoo.org>
---
 net-dns/pdns-recursor/Manifest                     |  2 +-
 net-dns/pdns-recursor/pdns-recursor-4.4.0.ebuild   | 84 ++++++++++++++++++++++
 .../pdns-recursor/pdns-recursor-4.4.0_rc2.ebuild   | 81 ---------------------
 3 files changed, 85 insertions(+), 82 deletions(-)
 create mode 100644 net-dns/pdns-recursor/pdns-recursor-4.4.0.ebuild
 delete mode 100644 net-dns/pdns-recursor/pdns-recursor-4.4.0_rc2.ebuild

(limited to 'net-dns')

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 32b5c61225bb..31ec9edb0695 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,2 +1,2 @@
 DIST pdns-recursor-4.3.5.tar.bz2 1341930 BLAKE2B 8f81182cb5283e6b8f459c5d23281d20cba02d22cec8776fdab67d452834b82945f467186c98784519d2c79d9df8438b174fc644fb11d68d04f9f636e51a5551 SHA512 2d39e6016000951c0beca38b26c41664b57c059dee762d7499f34e599ed6c2653af73edb31ba5a8d35f749534f24c0d85b6aedf4c35dc8a05777ffebd1b25851
-DIST pdns-recursor-4.4.0-rc2.tar.bz2 1393346 BLAKE2B 00f03dc05747e3b0962fdbff0e2d15b8e9d4703b84bafa086a5e1c229613b42d010ec963296845fe981c9bb99f02f8d60897fe180943091d0b904d0f65f453c0 SHA512 91f63924c30d89bf06dcaf48a588f116cedef530319b4e4682daf14682998b4879aca5d1796aa36a50ba327053523659f9a8ad180d592e5857f898e37f0064ec
+DIST pdns-recursor-4.4.0.tar.bz2 1395544 BLAKE2B 3e963a0e481db0d96813d5aa43e231548d765ecf7c18ce777ab3e1fb4b057722b257ec59ae95bf5cb11cb2f9114eb0e087aebecd4b19b96519e9a1e9cf6bb307 SHA512 06ec7788510b656ee8e08e54d989d8789685a3acb8b11172aff5de21bff493227368bbfca8203c56853da97d209facc4d88005b4b565a5986788a1b5f16a9fb6
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.4.0.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.4.0.ebuild
new file mode 100644
index 000000000000..6e6a0b941303
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.4.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit flag-o-matic
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap libressl luajit protobuf snmp sodium systemd"
+REQUIRED_USE="dnstap? ( protobuf )"
+
+DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
+	luajit? ( dev-lang/luajit:= )
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	libressl? ( dev-libs/libressl:= )
+	!libressl? ( dev-libs/openssl:= )
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua=$(usex luajit luajit lua) \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.4.0_rc2.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.4.0_rc2.ebuild
deleted file mode 100644
index ad0db27dfdf3..000000000000
--- a/net-dns/pdns-recursor/pdns-recursor-4.4.0_rc2.ebuild
+++ /dev/null
@@ -1,81 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-inherit flag-o-matic
-
-DESCRIPTION="The PowerDNS Recursor"
-HOMEPAGE="https://www.powerdns.com/"
-SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="" # ~amd64 ~arm ~x86
-IUSE="debug dnstap libressl luajit protobuf snmp sodium systemd"
-REQUIRED_USE="dnstap? ( protobuf )"
-
-DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
-	luajit? ( dev-lang/luajit:= )
-	protobuf? (
-		dev-libs/protobuf
-		>=dev-libs/boost-1.42:=
-	)
-	dnstap? ( dev-libs/fstrm )
-	systemd? ( sys-apps/systemd:0= )
-	snmp? ( net-analyzer/net-snmp )
-	sodium? ( dev-libs/libsodium:= )
-	libressl? ( dev-libs/libressl:= )
-	!libressl? ( dev-libs/openssl:= )
-	>=dev-libs/boost-1.35:="
-RDEPEND="${DEPEND}
-	!<net-dns/pdns-2.9.20-r1
-	acct-user/pdns
-	acct-group/pdns"
-BDEPEND="virtual/pkgconfig"
-
-S="${WORKDIR}"/${P/_/-}
-
-pkg_setup() {
-	filter-flags -ftree-vectorize
-}
-
-src_configure() {
-	econf \
-		--sysconfdir=/etc/powerdns \
-		--with-lua=$(usex luajit luajit lua) \
-		$(use_enable debug verbose-logging) \
-		$(use_enable systemd) \
-		$(use_enable dnstap dnstap) \
-		$(use_with sodium libsodium) \
-		$(use_with protobuf) \
-		$(use_with snmp net-snmp)
-}
-
-src_install() {
-	default
-
-	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
-
-	# set defaults: setuid=nobody, setgid=nobody
-	sed -i \
-		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
-		-e 's/^# quiet=$/quiet=on/' \
-		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
-		"${D}"/etc/powerdns/recursor.conf
-
-	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
-}
-
-pkg_postinst() {
-	local old
-
-	for old in ${REPLACING_VERSIONS}; do
-		ver_test ${old} -lt 4.0.0-r1 || continue
-
-		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
-		ewarn "to pdns-recursor, please update your runlevels accordingly."
-
-		break
-	done
-}
-- 
cgit v1.2.3-65-gdbad