Version bump thanks to Matt Drew in bug #167706, committed for Seemant

(Portage version: 2.1.2-r10)

3 files changed, 127 insertions, 1 deletions

diff --git a/app-office/gnucash/ChangeLog b/app-office/gnucash/ChangeLog
index 770c267f2d90..b09dd73b82af 100644
--- a/app-office/gnucash/ChangeLog
+++ b/app-office/gnucash/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/gnucash
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.121 2007/02/06 02:46:19 seemant Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.122 2007/02/20 21:24:34 dsd Exp $
+
+*gnucash-2.0.5 (20 Feb 2007)
+
+  20 Feb 2007; Daniel Drake <dsd@gentoo.org> +gnucash-2.0.5.ebuild:
+  Version bump thanks to Matt Drew in bug #167706, committed for Seemant
 
   06 Feb 2007; Seemant Kulleen <seemant@gentoo.org> gnucash-2.0.4-r1.ebuild:
   hard depend on guile-1.8 and above, and make sure it is built with
diff --git a/app-office/gnucash/files/digest-gnucash-2.0.5 b/app-office/gnucash/files/digest-gnucash-2.0.5
new file mode 100644
index 000000000000..0f11ee8951a7
--- /dev/null
+++ b/app-office/gnucash/files/digest-gnucash-2.0.5
@@ -0,0 +1,6 @@
+MD5 28f9b160fc01c4e597aca4c53d71fafe gnucash-2.0.5.tar.bz2 7372056
+RMD160 b3d853f376143121f29b14ff81d09e044183584f gnucash-2.0.5.tar.bz2 7372056
+SHA256 b7e2efcdc79ba864a1730af9e0197cdbf586c9008196eaffffce8f020f1fb479 gnucash-2.0.5.tar.bz2 7372056
+MD5 ffc058efd0283a4b43ca31980c40db49 gnucash-docs-2.0.1.tar.bz2 9262237
+RMD160 f2b00a5ce745921ea4e8a2360baff13aaf3fc083 gnucash-docs-2.0.1.tar.bz2 9262237
+SHA256 f39e6248fef20c761c74b534024869952e26b98879930b3a675178fd3d5260ff gnucash-docs-2.0.1.tar.bz2 9262237
diff --git a/app-office/gnucash/gnucash-2.0.5.ebuild b/app-office/gnucash/gnucash-2.0.5.ebuild
new file mode 100644
index 000000000000..060fefa7cd59
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.0.5.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.5.ebuild,v 1.1 2007/02/20 21:24:34 dsd Exp $
+
+inherit eutils gnome2
+
+DOC_VER="2.0.1"
+
+DESCRIPTION="A personal finance manager."
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-docs-${DOC_VER}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~sparc ~x86"
+
+IUSE="ofx hbci chipcard doc debug quotes nls"
+
+RDEPEND=">=dev-libs/glib-2.4.0
+	>=dev-scheme/guile-1.8
+	=dev-scheme/slib-3.1.1*
+	>=sys-libs/zlib-1.1.4
+	>=dev-libs/popt-1.5
+	>=x11-libs/gtk+-2.4
+	>=gnome-base/libgnomeui-2.4
+	>=gnome-base/libgnomeprint-2.10
+	>=gnome-base/libgnomeprintui-2.10
+	>=gnome-base/libglade-2.4
+	>=gnome-extra/gtkhtml-3.10.1
+	>=dev-libs/libxml2-2.5.10
+	=dev-libs/g-wrap-1.9.6*
+	>=gnome-base/gconf-2
+	>=app-text/scrollkeeper-0.3
+	>=x11-libs/goffice-0.0.4
+	gnome-extra/yelp
+	ofx? ( >=dev-libs/libofx-0.7.0 )
+	hbci? ( net-libs/aqbanking
+		chipcard? ( sys-libs/libchipcard )
+	)
+	quotes? ( dev-perl/DateManip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	app-text/docbook-xsl-stylesheets
+	=app-text/docbook-xml-dtd-4.1.2*
+	nls? ( dev-util/intltool )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen
+		media-gfx/graphviz
+		virtual/tetex )
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	built_with_use gnome-extra/libgsf gnome || die "gnome-extra/libgsf must be built with gnome"
+	built_with_use x11-libs/goffice gnome || die "x11-libs/goffice must be built with gnome"
+	built_with_use dev-scheme/guile regex || die "dev-scheme/guile must be built with regex"
+	built_with_use dev-scheme/guile deprecated || die "dev-scheme/guile must be built with deprecated"
+	built_with_use dev-scheme/guile discouraged || die "dev-scheme/guile must be built with discouraged"
+}
+
+src_compile() {
+
+	local myconf
+
+	if use doc ; then
+		myconf="${myconf} --enable-latex-docs"
+	fi
+
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable ofx) \
+		$(use_enable doc doxygen) \
+		$(use_enable doc html-docs) \
+		$(use_enable doc dot) \
+		$(use_enable hbci) \
+		$(use_enable hbci mt940) \
+		--enable-locale-specific-tax \
+		${myconf} || die "econf failed"
+
+	MAKEOPTS="-j1"
+	emake || die "emake failed"
+
+	cd "${WORKDIR}/gnucash-docs-${DOC_VER}"
+	econf || die "doc econf failed"
+	emake || die "doc emake failed"
+}
+
+src_test() {
+	einfo "Skipping tests because one of the upstream tests is broken"
+	einfo "Please reference: https://bugs.gentoo.org/show_bug.cgi?id=146769#c1"
+	einfo "We have a filed a bug upstream.  When that is resolved,"
+	einfo "We will re-enable the tests."
+}
+
+# See http://bugs.gentoo.org/show_bug.cgi?id=132862 regarding gconf schema install
+
+src_install() {
+	gnome2_src_install || die "gnome2_src_install failed"
+	dodoc AUTHORS ChangeLog* DOCUMENTERS HACKING INSTALL NEWS TODO README* doc/README*
+	make_desktop_entry ${P} "GnuCash ${PV}" gnucash-icon.png "GNOME;Office;Finance"
+
+	cd "${WORKDIR}/${PN}-docs-${DOC_VER}"
+	make DESTDIR="${D}" \
+		scrollkeeper_localstate_dir="${D}/var/lib/scrollkeeper" \
+		install || die "doc install failed"
+	rm -rf "${D}/var/lib/scrollkeeper"
+}
+
+pkg_postinst() {
+	elog "Please note that postgresql support has been removed."
+	elog "Please see: https://bugs.gentoo.org/show_bug.cgi?id=146769#c9"
+	elog "for an explanation."
+}