Revision bump, drop prolog support (bug #307015 by Robert Cabrera).

Clean up ebuild.
(Portage version: 2.2_rc63/cvs/Linux x86_64)

2 files changed, 70 insertions, 2 deletions

diff --git a/dev-libs/ppl/ChangeLog b/dev-libs/ppl/ChangeLog
index c6189a584319..e1578ca5270f 100644
--- a/dev-libs/ppl/ChangeLog
+++ b/dev-libs/ppl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/ppl
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ChangeLog,v 1.18 2009/09/19 23:30:17 aballier Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ChangeLog,v 1.19 2010/02/27 05:31:07 dirtyepic Exp $
+
+*ppl-0.10.2-r1 (27 Feb 2010)
+
+  27 Feb 2010; Ryan Hill <dirtyepic@gentoo.org> +ppl-0.10.2-r1.ebuild:
+  Revision bump, drop prolog support (bug #307015 by Robert Cabrera).
+  Clean up ebuild.
 
   19 Sep 2009; Alexis Ballier <aballier@gentoo.org> ppl-0.10.2.ebuild:
   keyword ~x86-fbsd
diff --git a/dev-libs/ppl/ppl-0.10.2-r1.ebuild b/dev-libs/ppl/ppl-0.10.2-r1.ebuild
new file mode 100644
index 000000000000..3970665f1373
--- /dev/null
+++ b/dev-libs/ppl/ppl-0.10.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ppl/ppl-0.10.2-r1.ebuild,v 1.1 2010/02/27 05:31:07 dirtyepic Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="The Parma Polyhedra Library provides numerical abstractions for analysis of complex systems"
+HOMEPAGE="http://www.cs.unipr.it/ppl/"
+SRC_URI="http://www.cs.unipr.it/ppl/Download/ftp/releases/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc pch test watchdog"
+
+RDEPEND=">=dev-libs/gmp-4.1.3[-nocxx]"
+DEPEND="${RDEPEND}
+		sys-devel/m4"
+
+pkg_setup() {
+	if use test; then
+		ewarn "The PPL testsuite will be run."
+		ewarn "Note that this can take several hours to complete on a fast machine."
+		epause 3
+	fi
+}
+
+src_configure() {
+	# --disable-check doesn't work
+	use test && want_check="--enable-check=quick"
+	econf                                   \
+		--docdir=/usr/share/doc/${PF}       \
+		--disable-debugging                 \
+		--disable-optimization              \
+		$(use_enable pch)                   \
+		$(use_enable watchdog)              \
+		--enable-interfaces="c cxx"         \
+		${want_check}                       \
+		|| die "configure failed"
+}
+
+src_test() {
+	# default src_test runs with -j1, overriding it here saves about
+	# 30 minutes and is recommended by upstream
+	if emake -j1 check -n &> /dev/null; then
+		emake check || die "tests failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+
+	if ! use doc; then
+		rm -r "${D}"/usr/share/doc/${PF}/ppl-user*-html
+		rm -r "${D}"/usr/share/doc/${PF}/pwl-user*-html
+	fi
+
+	cd "${S}"
+	dodoc NEWS README README.configure STANDARDS TODO
+}