Migrate to distutils-r1. Correct the swig dependency.

(Portage version: 2.2.0_alpha155/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 48 insertions, 3 deletions

diff --git a/dev-python/apse/ChangeLog b/dev-python/apse/ChangeLog
index 8e148c06c8bc..bf90068242e6 100644
--- a/dev-python/apse/ChangeLog
+++ b/dev-python/apse/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/apse
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/apse/ChangeLog,v 1.11 2012/02/21 05:02:17 patrick Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apse/ChangeLog,v 1.12 2013/01/20 00:45:10 mgorny Exp $
+
+*apse-0.2-r2 (20 Jan 2013)
+
+  20 Jan 2013; Michał Górny <mgorny@gentoo.org> +apse-0.2-r2.ebuild:
+  Migrate to distutils-r1. Correct the swig dependency.
 
   21 Feb 2012; Patrick Lauer <patrick@gentoo.org> apse-0.2-r1.ebuild:
   Restricting jython
@@ -42,4 +47,3 @@
   24 Jan 2005; Christian Andreetta <satya@gentoo.org> +metadata.xml,
   +apse-0.2.ebuild:
   New package submission
-
diff --git a/dev-python/apse/apse-0.2-r2.ebuild b/dev-python/apse/apse-0.2-r2.ebuild
new file mode 100644
index 000000000000..36a0e7be3d69
--- /dev/null
+++ b/dev-python/apse/apse-0.2-r2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apse/apse-0.2-r2.ebuild,v 1.1 2013/01/20 00:45:10 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+MY_P="Apse-${PV}"
+
+DESCRIPTION="Approximate String Matching in Python."
+HOMEPAGE="http://www.personal.psu.edu/staff/i/u/iua1/python/apse/"
+SRC_URI="http://www.personal.psu.edu/staff/i/u/iua1/python/${PN}/dist/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND="<dev-lang/swig-2"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Prevent the build system from calling swig over and over again.
+	sed -i -e 's:Apse.i:Apse_wrap.c:' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	set -- swig -python -o Apse_wrap.c Apse.i
+	echo "${@}" >&2
+	"${@}" || die
+}
+
+python_test() {
+	"${PYTHON}" test/test_Apse.py || die "Tests fail with ${EPYTHON}"
+}