Migrate to distutils-r1.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 75 insertions, 2 deletions

diff --git a/dev-python/gevent/ChangeLog b/dev-python/gevent/ChangeLog
index 9939042cdb23..103e418cf4df 100644
--- a/dev-python/gevent/ChangeLog
+++ b/dev-python/gevent/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/gevent
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.8 2012/11/13 10:50:41 idella4 Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/ChangeLog,v 1.9 2013/02/05 23:40:02 mgorny Exp $
+
+*gevent-1.0_beta2-r1 (05 Feb 2013)
+
+  05 Feb 2013; Michał Górny <mgorny@gentoo.org> +gevent-1.0_beta2-r1.ebuild:
+  Migrate to distutils-r1.
 
   14 Nov 2012; Ian Delaney <idella4@gentoo.org> metadata.xml:
   Updating maintainer, metadata.xml
diff --git a/dev-python/gevent/gevent-1.0_beta2-r1.ebuild b/dev-python/gevent/gevent-1.0_beta2-r1.ebuild
new file mode 100644
index 000000000000..632f182a36da
--- /dev/null
+++ b/dev-python/gevent/gevent-1.0_beta2-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/gevent-1.0_beta2-r1.ebuild,v 1.1 2013/02/05 23:40:02 mgorny Exp $
+
+EAPI=5
+
+# py2.5 needs http://pypi.python.org/pypi/ssl
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="ssl"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python networking library that uses greenlet to provide synchronous API"
+HOMEPAGE="http://code.google.com/p/gevent/ http://pypi.python.org/pypi/gevent/"
+SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc examples"
+
+RDEPEND="dev-libs/libev
+	net-dns/c-ares
+	dev-python/greenlet[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Tests take long and fail terribly a few times.
+# It also seems that they require network access.
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	rm -rf {libev,c-ares}
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	cd greentest || die
+	"${PYTHON}" testrunner.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+
+	dodoc changelog.rst
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}