version bump

(Portage version: 2.1.6.13/cvs/Linux i686)

2 files changed, 78 insertions, 1 deletions

diff --git a/games-puzzle/jag/ChangeLog b/games-puzzle/jag/ChangeLog
index af836c23fb44..b289cfa5e564 100644
--- a/games-puzzle/jag/ChangeLog
+++ b/games-puzzle/jag/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-puzzle/jag
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-puzzle/jag/ChangeLog,v 1.6 2009/12/19 19:21:02 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/jag/ChangeLog,v 1.7 2009/12/30 15:59:58 mr_bones_ Exp $
+
+*jag-0.3.0 (30 Dec 2009)
+
+  30 Dec 2009; Michael Sterrett <mr_bones_@gentoo.org> +jag-0.3.0.ebuild:
+  version bump
 
   19 Dec 2009; Pacho Ramos <pacho@gentoo.org> jag-0.2.6.ebuild:
   amd64 stable, bug 295703
diff --git a/games-puzzle/jag/jag-0.3.0.ebuild b/games-puzzle/jag/jag-0.3.0.ebuild
new file mode 100644
index 000000000000..63264e37fc34
--- /dev/null
+++ b/games-puzzle/jag/jag-0.3.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/jag/jag-0.3.0.ebuild,v 1.1 2009/12/30 15:59:58 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils qt4 games
+
+DESCRIPTION="Arcade 2D Puzzle Game"
+HOMEPAGE="http://jag.xlabsoft.com/"
+SRC_URI="http://jag.xlabsoft.com/files/${P}-src.zip
+	http://jag.xlabsoft.com/files/jag_levels_sunzero.zip
+	extras? ( http://jag.xlabsoft.com/files/jag_seven_themes.zip )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="editor extras"
+
+RDEPEND="x11-libs/qt-core:4
+	x11-libs/qt-gui:4
+	x11-libs/qt-opengl:4
+	x11-libs/libXrandr
+	media-libs/libsdl[audio,video]
+	media-libs/sdl-mixer"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${P}-src
+
+src_prepare() {
+	sed -i \
+		-e "s:/usr/local/bin:${GAMES_BINDIR}:g" \
+		-e "s:/usr/local/games:${GAMES_DATADIR}:g" \
+		-e "s:LIBS += -lSDLmain:LIBS += -lSDL:" \
+		Game.pro main.cpp editor/editor.pro \
+		|| die "sed failed"
+}
+
+src_configure() {
+	eqmake4 Game.pro
+	if use editor; then
+		cd editor
+		eqmake4 editor.pro
+	fi
+}
+
+src_compile() {
+	emake || die
+	if use editor; then
+		emake -C editor || die
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die
+	newicon images/logo.png ${PN}.png
+	make_desktop_entry jag Jag
+
+	if use editor; then
+		emake -C editor INSTALL_ROOT="${D}" install || die
+		make_desktop_entry jag-editor "Jag Level editor" ${PN}
+	fi
+
+	insinto "${GAMES_DATADIR}/${PN}"/data/levels
+	doins -r "${WORKDIR}"/sunzero.lpk || die "doins failed"
+
+	if use extras; then
+		insinto "${GAMES_DATADIR}/${PN}"/data/schemes
+		doins -r "${WORKDIR}"/{african,animals,chinese,creatures,futurama,kde-nuvola,toys} || die "doins failed"
+	fi
+	prepgamesdirs
+}