Version bump KDE SC 4.8.2

(Portage version: 2.2.0_alpha98/cvs/Linux i686)

2 files changed, 100 insertions, 1 deletions

diff --git a/kde-base/systemsettings/ChangeLog b/kde-base/systemsettings/ChangeLog
index 64895f060861..5e9c98f7973b 100644
--- a/kde-base/systemsettings/ChangeLog
+++ b/kde-base/systemsettings/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.141 2012/04/04 19:28:48 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.142 2012/04/04 23:59:34 johu Exp $
+
+*systemsettings-4.8.2 (04 Apr 2012)
+
+  04 Apr 2012; Johannes Huber <johu@gentoo.org> +systemsettings-4.8.2.ebuild:
+  Version bump KDE SC 4.8.2
 
   04 Apr 2012; Agostino Sarubbo <ago@gentoo.org> systemsettings-4.8.1.ebuild:
   Stable for amd64, wrt bug #409403
diff --git a/kde-base/systemsettings/systemsettings-4.8.2.ebuild b/kde-base/systemsettings/systemsettings-4.8.2.ebuild
new file mode 100644
index 000000000000..df1cdb27440e
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-4.8.2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.8.2.ebuild,v 1.1 2012/04/04 23:59:34 johu Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde4-meta
+
+DESCRIPTION="System settings utility"
+IUSE="debug gtk +usb xinerama"
+KEYWORDS="~amd64 ~arm ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+COMMONDEPEND="
+	dev-libs/glib:2
+	$(add_kdebase_dep libkworkspace)
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=x11-libs/libxklavier-3.2
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	opengl? ( virtual/opengl )
+	usb? ( =virtual/libusb-0* )
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/kbproto
+	x11-proto/xextproto
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}
+	sys-libs/timezone-data
+	x11-apps/setxkbmap
+	x11-misc/xkeyboard-config
+	gtk? ( kde-misc/kcm-gtk-config )
+"
+
+KMEXTRA="
+	kcontrol/
+"
+KMEXTRACTONLY="
+	krunner/dbus/org.kde.krunner.App.xml
+	krunner/dbus/org.kde.screensaver.xml
+	kwin/
+	libs/
+	plasma/
+"
+
+add_blocker kdeaccessibility-colorschemes '<4.6.50'
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.4.2-xinerama_cmake_automagic.patch"
+)
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+="
+			doc/kcontrol
+			doc/kfontview
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_prepare() {
+	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
+		systemsettings/CMakeLists.txt \
+		|| die "Failed to fix systemsettingsrc install location"
+
+	kde4-meta_src_prepare
+}
+
+# FIXME: is have_openglxvisual found without screensaver
+src_configure() {
+	# Old keyboard-detection code is unmaintained,
+	# so we force the new stuff, using libxklavier.
+	mycmakeargs=(
+		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
+		-DWITH_GLIB2=ON -DWITH_GObject=ON
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with usb)
+		$(cmake-utils_use_with xinerama X11_Xinerama)
+	)
+
+	kde4-meta_src_configure
+}