Enable multilib support.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 62 insertions, 3 deletions

diff --git a/media-libs/libofa/ChangeLog b/media-libs/libofa/ChangeLog
index fed4afe5b4f4..f2c33857aaac 100644
--- a/media-libs/libofa/ChangeLog
+++ b/media-libs/libofa/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libofa
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libofa/ChangeLog,v 1.24 2012/06/04 12:51:28 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libofa/ChangeLog,v 1.25 2014/06/07 15:27:00 mgorny Exp $
+
+*libofa-0.9.3-r1 (07 Jun 2014)
+
+  07 Jun 2014; Michał Górny <mgorny@gentoo.org> +libofa-0.9.3-r1.ebuild:
+  Enable multilib support.
 
   04 Jun 2012; Justin Lecher <jlec@gentoo.org> libofa-0.9.3.ebuild,
   +files/libofa-0.9.3-gcc-4.7.patch:
@@ -82,4 +87,3 @@
   27 Aug 2006; Carsten Lohrke <carlo@gentoo.org> +metadata.xml,
   +libofa-0.9.3.ebuild:
   Initial commit. Thanks to Maxwell Gender-Jones, bug #126069.
-
diff --git a/media-libs/libofa/libofa-0.9.3-r1.ebuild b/media-libs/libofa/libofa-0.9.3-r1.ebuild
new file mode 100644
index 000000000000..0e85d804a305
--- /dev/null
+++ b/media-libs/libofa/libofa-0.9.3-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libofa/libofa-0.9.3-r1.ebuild,v 1.1 2014/06/07 15:27:00 mgorny Exp $
+
+EAPI=5
+
+inherit eutils flag-o-matic multilib-minimal
+
+DESCRIPTION="Open Fingerprint Architecture"
+HOMEPAGE="http://code.google.com/p/musicip-libofa/"
+SRC_URI="http://musicip-libofa.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="|| ( APL-1.0 GPL-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="dev-libs/expat
+	net-misc/curl
+	>=sci-libs/fftw-3[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+RDEPEND="${RDEPEND}
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20140508-r2
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-4.patch
+	"${FILESDIR}"/${P}-gcc-4.3.patch
+	"${FILESDIR}"/${P}-gcc-4.4.patch
+	"${FILESDIR}"/${P}-gcc-4.7.patch
+)
+
+src_prepare() {
+	# disable building non-installed examples
+	sed -i -e '/SUBDIRS/s:examples::' Makefile.{am,in} || die
+
+	epatch "${PATCHES[@]}"
+	epatch_user
+
+	is-flag -ffast-math && append-flags -fno-fast-math
+}
+
+multilib_src_configure() {
+	# disable dependencies that were used for the noinst_ example only
+
+	ECONF_SOURCE=${S} \
+	econf \
+		ac_cv_lib_expat_XML_ExpatVersion=yes \
+		ac_cv_lib_curl_curl_global_init=yes
+}
+
+multilib_src_install_all() {
+	dodoc AUTHORS README
+}