Use more recent s-s-d syntax wrt #380279 by Tom Hendrikx

(Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

1 files changed, 68 insertions, 0 deletions

diff --git a/media-video/motion/motion-3.2.12-r1.ebuild b/media-video/motion/motion-3.2.12-r1.ebuild
new file mode 100644
index 000000000000..e0d6fde5695f
--- /dev/null
+++ b/media-video/motion/motion-3.2.12-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/motion/motion-3.2.12-r1.ebuild,v 1.1 2011/10/02 18:48:35 ssuominen Exp $
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="A software motion detector"
+HOMEPAGE="http://www.lavrsen.dk/twiki/bin/view/Motion/WebHome"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86"
+IUSE="ffmpeg mysql postgres v4l"
+
+RDEPEND="sys-libs/zlib
+	virtual/jpeg
+	ffmpeg? ( virtual/ffmpeg )
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )"
+DEPEND="${RDEPEND}
+	v4l? ( virtual/os-headers )"
+
+pkg_setup() {
+	enewuser motion -1 -1 -1 video
+}
+
+src_configure() {
+	local hack
+	if has_version '>=sys-kernel/linux-headers-2.6.38'; then
+		hack="--without-v4l" #361509
+		ewarn "Disabling video4linux support because of too new"
+		ewarn "linux-headers. See bug 376225 for new motion."
+	fi
+
+	econf \
+		$(use_with v4l) \
+		$(use_with ffmpeg) \
+		$(use_with mysql) \
+		$(use_with postgres pgsql) \
+		--without-optimizecpu \
+		${hack}
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		DOC='CHANGELOG CODE_STANDARD CREDITS FAQ README' \
+		docdir=/usr/share/doc/${PF} \
+		EXAMPLES='thread*.conf' \
+		examplesdir=/usr/share/doc/${PF}/examples \
+		install
+
+	dohtml *.html
+
+	newinitd "${FILESDIR}"/motion.initd-r2 motion
+	newconfd "${FILESDIR}"/motion.confd motion
+
+	mv -vf "${D}"/etc/motion{-dist,}.conf || die
+}
+
+pkg_postinst() {
+	elog "You need to setup /etc/motion.conf before running"
+	elog "motion for the first time."
+	elog "You can install motion detection as a service, use:"
+	elog "rc-update add motion default"
+}