use ecvs_clean; Bump to EAPI=5

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 113 insertions, 13 deletions

diff --git a/net-irc/ptlink-ircd/ChangeLog b/net-irc/ptlink-ircd/ChangeLog
index 30079c99395d..4fc164d88d60 100644
--- a/net-irc/ptlink-ircd/ChangeLog
+++ b/net-irc/ptlink-ircd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/ptlink-ircd
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-ircd/ChangeLog,v 1.16 2014/08/10 20:53:43 slyfox Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-ircd/ChangeLog,v 1.17 2015/03/21 13:55:32 jlec Exp $
+
+*ptlink-ircd-6.19.6-r2 (21 Mar 2015)
+
+  21 Mar 2015; Justin Lecher <jlec@gentoo.org> +ptlink-ircd-6.19.6-r2.ebuild,
+  ptlink-ircd-6.19.6-r1.ebuild:
+  use ecvs_clean; Bump to EAPI=5
 
   10 Aug 2014; Sergei Trofimovich <slyfox@gentoo.org>
   ptlink-ircd-6.19.6-r1.ebuild:
diff --git a/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild b/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild
index d20fb88ef734..a63f4c7449f4 100644
--- a/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild
+++ b/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild,v 1.4 2014/08/10 20:53:43 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r1.ebuild,v 1.5 2015/03/21 13:55:32 jlec Exp $
 
 inherit eutils ssl-cert user
 
@@ -9,26 +9,27 @@ MY_P="PTlink${PV}"
 DESCRIPTION="PTlink IRCd is a secure IRC daemon with many advanced features"
 HOMEPAGE="http://www.ptlink.net/"
 SRC_URI="ftp://ftp.sunsite.dk/projects/ptlink/ircd/${MY_P}.tar.gz"
+
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~ppc ~sparc ~x86"
-
 IUSE="ssl"
-DEPEND="sys-libs/zlib
+
+DEPEND="
+	sys-libs/zlib
 	ssl? ( dev-libs/openssl )"
 
 S=${WORKDIR}/${MY_P}
 
 src_unpack() {
 	unpack ${A}
-	find "${S}" -type d -name CVS -print0 2>/dev/null | xargs -0r rm -rf
+	ecvs_clean
 }
 
 src_compile() {
 	econf \
 		--disable-ipv6 \
-		$(use_with ssl ssl openssl) \
-		|| die "econf failed"
+		$(use_with ssl ssl openssl)
 	emake CFLAGS="${CFLAGS}" || die "emake failed"
 }
 
@@ -76,13 +77,13 @@ pkg_postinst() {
 		"${ROOT}"/{etc,var/{log,lib}}/ptlink-ircd \
 		"${ROOT}"/etc/ptlink-ircd/server.key.pem
 
-	elog
+	echo
 	elog "PTlink IRCd will run without configuration, although this is strongly"
 	elog "advised against."
-	elog
+	echo
 	elog "You can find example cron script ircd.cron here:"
 	elog "   /usr/share/doc/${PF}"
-	elog
+	echo
 	elog "You can also use /etc/init.d/ptlink-ircd to start at boot"
-	elog
+	echo
 }
diff --git a/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r2.ebuild b/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r2.ebuild
new file mode 100644
index 000000000000..2334bc1ae047
--- /dev/null
+++ b/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/ptlink-ircd/ptlink-ircd-6.19.6-r2.ebuild,v 1.1 2015/03/21 13:55:32 jlec Exp $
+
+EAPI=5
+
+inherit eutils ssl-cert user
+
+MY_P="PTlink${PV}"
+
+DESCRIPTION="Secure IRC daemon with many advanced features"
+HOMEPAGE="http://www.ptlink.net/"
+SRC_URI="ftp://ftp.sunsite.dk/projects/ptlink/ircd/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~ppc ~sparc ~x86"
+IUSE="ssl"
+
+DEPEND="
+	sys-libs/zlib
+	ssl? ( dev-libs/openssl:0= )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	ecvs_clean
+}
+
+src_configure() {
+	econf \
+		--disable-ipv6 \
+		$(use_with ssl ssl openssl)
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	newbin src/ircd ptlink-ircd
+	newbin tools/fixklines ptlink-ircd-fixklines
+	newbin tools/mkpasswd ptlink-ircd-mkpasswd
+
+	insinto /etc/ptlink-ircd
+	fperms 700 /etc/ptlink-ircd
+	doins samples/{kline.conf,{opers,ptlink}.motd,help.{admin,oper,user}}
+	newins samples/example.conf.short ircd.conf
+	newins samples/example.conf.trillian ircd.conf.trillian
+	newins samples/main.dconf.sample main.dconf
+	newins samples/network.dconf.sample network.dconf
+
+	insinto /usr/share/ptlink-ircd/codepage
+	doins src/codepage/*.enc
+	dosym /usr/share/ptlink-ircd/codepage /etc/ptlink-ircd/codepage
+
+	rm -rf doc/old
+	dodoc doc/* doc_hybrid6/* ircdcron/* CHANGES README
+
+	keepdir /var/log/ptlink-ircd /var/lib/ptlink-ircd
+	dosym /var/log/ptlink-ircd /var/lib/ptlink-ircd/log
+
+	newinitd "${FILESDIR}/ptlink-ircd.initd" ptlink-ircd
+	newconfd "${FILESDIR}/ptlink-ircd.confd" ptlink-ircd
+}
+
+pkg_postinst() {
+	# Move docert from src_install() to install_cert for bug #201678
+	use ssl && (
+		if [[ ! -f "${ROOT}"/etc/ptlink-ircd/server.key.pem ]]; then
+			install_cert /etc/ptlink-ircd/server || die "install_cert failed"
+			mv "${ROOT}"/etc/ptlink-ircd/server.{crt,cert.pem}
+			mv "${ROOT}"/etc/ptlink-ircd/server.{csr,req.pem}
+			mv "${ROOT}"/etc/ptlink-ircd/server.key{,.pem}
+		fi
+	)
+
+	enewuser ptlink-ircd
+
+	chown ptlink-ircd \
+		"${ROOT}"/{etc,var/{log,lib}}/ptlink-ircd \
+		"${ROOT}"/etc/ptlink-ircd/server.key.pem
+
+	echo
+	elog "PTlink IRCd will run without configuration, although this is strongly"
+	elog "advised against."
+	echo
+	elog "You can find example cron script ircd.cron here:"
+	elog "   /usr/share/doc/${PF}"
+	echo
+	elog "You can also use /etc/init.d/ptlink-ircd to start at boot"
+	echo
+}