Version bump

(Portage version: 2.2.0_alpha50/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/net-libs/libssh/ChangeLog b/net-libs/libssh/ChangeLog
index 7a8b9dcf0aac..2eea914999c5 100644
--- a/net-libs/libssh/ChangeLog
+++ b/net-libs/libssh/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libssh
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.50 2011/08/07 14:21:52 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.51 2011/08/10 22:09:42 radhermit Exp $
+
+*libssh-0.5.1 (10 Aug 2011)
+
+  10 Aug 2011; Tim Harder <radhermit@gentoo.org> +libssh-0.5.1.ebuild:
+  Version bump
 
   07 Aug 2011; Raúl Porcel <armin76@gentoo.org> libssh-0.5.0.ebuild:
   Add ~s390/~sparc wrt #374401
diff --git a/net-libs/libssh/libssh-0.5.1.ebuild b/net-libs/libssh/libssh-0.5.1.ebuild
new file mode 100644
index 000000000000..ebafbea985c3
--- /dev/null
+++ b/net-libs/libssh/libssh-0.5.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.5.1.ebuild,v 1.1 2011/08/10 22:09:42 radhermit Exp $
+
+EAPI=4
+
+inherit eutils cmake-utils
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="http://www.libssh.org/"
+SRC_URI="http://www.${PN}.org/files/${PV:0:3}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86"
+SLOT="0"
+IUSE="debug doc examples gcrypt pcap +sftp ssh1 server static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+RDEPEND="
+	zlib? ( >=sys-libs/zlib-1.2 )
+	!gcrypt? ( >=dev-libs/openssl-0.9.8 )
+	gcrypt? ( >=dev-libs/libgcrypt-1.4 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cmockery )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+src_prepare() {
+	# just install the examples do not compile them
+	sed -i \
+		-e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
+		CMakeLists.txt || die
+
+	epatch "${FILESDIR}"/${PN}-0.5.0-no-pdf-doc.patch \
+		"${FILESDIR}"/${PN}-0.5.0-tests.patch
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
+		$(cmake-utils_use_with debug DEBUG_CRYPTO)
+		$(cmake-utils_use_with gcrypt)
+		$(cmake-utils_use_with pcap)
+		$(cmake-utils_use_with server)
+		$(cmake-utils_use_with sftp)
+		$(cmake-utils_use_with ssh1)
+		$(cmake-utils_use_with static-libs STATIC_LIB)
+		$(cmake-utils_use_with test TESTING)
+		$(cmake-utils_use_with zlib LIBZ)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_compile doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,cpp}
+	fi
+}