sci-chemistry/pymol: Version Bump

(Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

3 files changed, 102 insertions, 3 deletions

diff --git a/sci-chemistry/pymol/ChangeLog b/sci-chemistry/pymol/ChangeLog
index 3ecf5dbf0e9a..f1b55436410d 100644
--- a/sci-chemistry/pymol/ChangeLog
+++ b/sci-chemistry/pymol/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-chemistry/pymol
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.99 2013/03/19 09:07:34 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/ChangeLog,v 1.100 2013/03/25 07:55:32 jlec Exp $
+
+*pymol-1.6.0_rc1 (25 Mar 2013)
+
+  25 Mar 2013; Justin Lecher <jlec@gentoo.org> pymol-1.5.0.3-r2.ebuild,
+  +pymol-1.6.0_rc1.ebuild:
+  Version Bump
 
   19 Mar 2013; Justin Lecher <jlec@gentoo.org> pymol-1.5.0.3-r2.ebuild:
   Prefix love
diff --git a/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild b/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild
index ec5d706ae68e..f256ad2bfe62 100644
--- a/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild
+++ b/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild,v 1.2 2013/03/19 09:07:34 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.5.0.3-r2.ebuild,v 1.3 2013/03/25 07:55:32 jlec Exp $
 
 EAPI=5
 
@@ -21,7 +21,7 @@ KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
 IUSE="apbs numpy vmd web"
 
 DEPEND="
-	dev-python/numpy
+	dev-python/numpy[${PYTHON_USEDEP}]
 	dev-python/pmw[${PYTHON_USEDEP}]
 	media-libs/freetype:2
 	media-libs/glew
diff --git a/sci-chemistry/pymol/pymol-1.6.0_rc1.ebuild b/sci-chemistry/pymol/pymol-1.6.0_rc1.ebuild
new file mode 100644
index 000000000000..45346bfcc0a8
--- /dev/null
+++ b/sci-chemistry/pymol/pymol-1.6.0_rc1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/pymol/pymol-1.6.0_rc1.ebuild,v 1.1 2013/03/25 07:55:32 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="tk"
+
+inherit distutils-r1 fdo-mime versionator
+
+DESCRIPTION="A Python-extensible molecular graphics system"
+HOMEPAGE="http://pymol.sourceforge.net/"
+SRC_URI="
+	http://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz
+	http://dev.gentoo.org/~jlec/distfiles/${PN}-icons.tar.xz"
+
+LICENSE="PSF-2.2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="apbs web"
+
+DEPEND="
+	dev-python/pmw[${PYTHON_USEDEP}]
+	media-libs/freetype:2
+	media-libs/glew
+	media-libs/libpng
+	media-video/mpeg-tools
+	sys-libs/zlib
+	media-libs/freeglut
+	apbs? (
+		dev-libs/maloc
+		sci-chemistry/apbs
+		sci-chemistry/pdb2pqr
+		sci-chemistry/pymol-apbs-plugin
+	)
+	web? ( !dev-python/webpy )"
+RDEPEND="${DEPEND}"
+
+python_prepare_all() {
+	sed \
+		-e "s:\"/usr:\"${EPREFIX}/usr:g" \
+		-e "/ext_comp_args/s:=\[.*\]$:= \[\]:g" \
+		-i setup.py || die
+
+	rm ./modules/pmg_tk/startup/apbs_tools.py || die
+
+	sed \
+		-e "s:/opt/local:${EPREFIX}/usr:g" \
+		-e '/ext_comp_args/s:\[.*\]:[]:g' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install --pymol-path="${EPREFIX}/usr/share/pymol"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	python_export python2_7 EPYTHON
+
+	# These environment variables should not go in the wrapper script, or else
+	# it will be impossible to use the PyMOL libraries from Python.
+	cat >> "${T}"/20pymol <<- EOF
+		PYMOL_PATH="$(python_get_sitedir)/${PN}"
+		PYMOL_DATA="${EPREFIX}/usr/share/pymol/data"
+		PYMOL_SCRIPTS="${EPREFIX}/usr/share/pymol/scripts"
+	EOF
+
+	doenvd "${T}"/20pymol
+
+	doicon "${WORKDIR}"/${PN}.{xpm,png}
+	make_desktop_entry pymol PyMol ${PN} "Graphics;Education;Science;Chemistry" "MimeType=chemical/x-pdb;"
+
+	if ! use web; then
+		rm -rf "${D}/$(python_get_sitedir)/web" || die
+	fi
+
+	rm -f "${ED}"/usr/share/${PN}/LICENSE || die
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}