Version bump wrt #395085 by Hannan Sadar

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

2 files changed, 65 insertions, 2 deletions

diff --git a/sys-libs/gwenhywfar/ChangeLog b/sys-libs/gwenhywfar/ChangeLog
index f71e63c9e735..0dec95eeebe6 100644
--- a/sys-libs/gwenhywfar/ChangeLog
+++ b/sys-libs/gwenhywfar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/gwenhywfar
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/gwenhywfar/ChangeLog,v 1.91 2011/08/21 19:57:08 hanno Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/gwenhywfar/ChangeLog,v 1.92 2012/01/06 09:09:21 ssuominen Exp $
+
+*gwenhywfar-4.3.1 (06 Jan 2012)
+
+  06 Jan 2012; Samuli Suominen <ssuominen@gentoo.org> +gwenhywfar-4.3.1.ebuild:
+  Version bump wrt #395085 by Hannan Sadar
 
 *gwenhywfar-4.2.1 (21 Aug 2011)
 
diff --git a/sys-libs/gwenhywfar/gwenhywfar-4.3.1.ebuild b/sys-libs/gwenhywfar/gwenhywfar-4.3.1.ebuild
new file mode 100644
index 000000000000..73883d5f65a2
--- /dev/null
+++ b/sys-libs/gwenhywfar/gwenhywfar-4.3.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/gwenhywfar/gwenhywfar-4.3.1.ebuild,v 1.1 2012/01/06 09:09:21 ssuominen Exp $
+
+EAPI=4
+
+DESCRIPTION="A multi-platform helper library for other libraries"
+HOMEPAGE="http://www.aquamaniac.de/aqbanking/"
+SRC_URI="http://www.aquamaniac.de/sites/download/download.php?package=01&release=65&file=01&dummy=${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug doc fox gtk qt4"
+
+RDEPEND="dev-libs/libgpg-error
+	>=dev-libs/libgcrypt-1.2.0
+	dev-libs/openssl:0
+	>=net-libs/gnutls-2.0.1
+	virtual/libiconv
+	virtual/libintl
+	fox? ( x11-libs/fox:1.6 )
+	gtk? ( >=x11-libs/gtk+-2.17.5:2 )
+	qt4? ( x11-libs/qt-gui:4 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/gettext
+	doc? ( app-doc/doxygen )"
+
+# broken upstream, reported but got no reply
+RESTRICT="test"
+
+src_configure() {
+	local guis
+	use fox && guis="${guis} fox16"
+	use gtk && guis="${guis} gtk2"
+	use qt4 && guis="${guis} qt4"
+
+	econf \
+		--enable-ssl \
+		--enable-visibility \
+		$(use_enable debug) \
+		$(use_enable doc full-doc) \
+		--with-guis="${guis}" \
+		--with-docpath=/usr/share/doc/${PF}/apidoc
+}
+
+src_compile() {
+	emake
+	use doc && emake srcdoc
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	use doc && emake DESTDIR="${D}" install-srcdoc
+	dodoc AUTHORS ChangeLog README TODO
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}