Version bumped.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

2 files changed, 98 insertions, 1 deletions

diff --git a/x11-terms/mlterm/ChangeLog b/x11-terms/mlterm/ChangeLog
index 5b92fdf4bb11..a9a540231872 100644
--- a/x11-terms/mlterm/ChangeLog
+++ b/x11-terms/mlterm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/mlterm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.78 2011/06/09 14:55:41 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.79 2011/08/18 02:19:26 naota Exp $
+
+*mlterm-3.0.6 (18 Aug 2011)
+
+  18 Aug 2011; Naohiro Aota <naota@gentoo.org> +mlterm-3.0.6.ebuild:
+  Version bumped.
 
 *mlterm-3.0.5 (09 Jun 2011)
 
diff --git a/x11-terms/mlterm/mlterm-3.0.6.ebuild b/x11-terms/mlterm/mlterm-3.0.6.ebuild
new file mode 100644
index 000000000000..3c57bf1a8ff2
--- /dev/null
+++ b/x11-terms/mlterm/mlterm-3.0.6.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/mlterm-3.0.6.ebuild,v 1.1 2011/08/18 02:19:26 naota Exp $
+
+EAPI="3"
+inherit autotools eutils
+
+IUSE="bidi debug gtk ibus libssh2 m17n-lib nls scim static-libs uim xft"
+
+DESCRIPTION="A multi-lingual terminal emulator"
+HOMEPAGE="http://mlterm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mlterm/${P}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+LICENSE="BSD"
+
+RDEPEND="|| ( sys-libs/libutempter sys-apps/utempter )
+	x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	gtk? ( x11-libs/gtk+:2 )
+	xft? ( x11-libs/libXft )
+	bidi? ( >=dev-libs/fribidi-0.10.4 )
+	ibus? ( >=app-i18n/ibus-1.3 )
+	libssh2? ( net-libs/libssh2 )
+	nls? ( virtual/libintl )
+	uim? ( >=app-i18n/uim-1.0 )
+	scim? ( >=app-i18n/scim-1.4 )
+	m17n-lib? ( >=dev-libs/m17n-lib-1.2.0 )"
+#	vte? ( x11-libs/vte )
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-2.9.4-uim15-fix.patch \
+		"${FILESDIR}"/${PN}-3.0.5-ldflags.patch \
+		"${FILESDIR}"/${PN}-3.0.5-ibus.patch
+
+	eautoconf
+}
+
+src_configure() {
+	local myconf
+
+	if use gtk ; then
+		myconf="${myconf} --with-imagelib=gdk-pixbuf"
+	else
+		myconf="${myconf} --with-tools=mlclient,mlcc"
+	fi
+
+	if use xft ; then
+		myconf="${myconf} --with-type-engines=xft"
+	else
+		myconf="${myconf} --with-type-engines=xcore"
+	fi
+
+	# iiimf isn't stable enough
+	#myconf="${myconf} $(use_enable iiimf)"
+
+	econf --enable-utmp \
+		$(use_enable bidi fribidi) \
+		$(use_enable debug) \
+		$(use_enable ibus) \
+		$(use_enable libssh2 ssh2) \
+		$(use_enable nls) \
+		$(use_enable uim) \
+		$(use_enable scim) \
+		$(use_enable m17n-lib m17nlib) \
+		$(use_enable static-libs static) \
+		${myconf} || die "econf failed"
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die
+
+	if ! use static-libs ; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+
+	doicon contrib/icon/mlterm* || die
+	make_desktop_entry mlterm mlterm mlterm-icon TerminalEmulator || die
+
+	dodoc ChangeLog README || die
+
+	docinto ja
+	dodoc doc/ja/* || die
+	docinto en
+	dodoc doc/en/* || die
+}