x11-misc/notification-daemon-xfce/notification-daemon-xfce-0.3.7.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/notification-daemon-xfce/notification-daemon-xfce-0.3.7.ebuild,v 1.9 2009/06/09 17:45:01 darkside Exp $

EAPI=1

inherit autotools eutils gnome2-utils

DESCRIPTION="Port of notification daemon for Xfce Desktop Environment"
HOMEPAGE="http://goodies.xfce.org/projects/applications/notification-daemon-xfce"
SRC_URI="http://goodies.xfce.org/releases/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm ia64 ppc ~ppc64 sparc x86 ~x86-fbsd"
IUSE="debug +xfce"

RDEPEND=">=dev-libs/glib-2.6
	>=x11-libs/gtk+-2.6
	x11-libs/libnotify
	>=xfce-base/libxfcegui4-4.3.90
	>=xfce-base/libxfce4util-4.3.90
	xfce? ( || ( xfce-base/xfce4-settings >=xfce-base/xfce-mcs-manager-4.2.2  ) )
	>=x11-libs/libsexy-0.1.3
	dev-libs/dbus-glib"
DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig
	sys-devel/gettext
	dev-util/xfce4-dev-tools
	!x11-misc/notification-daemon
	!x11-misc/xfce4-notifyd"

src_unpack() {
	unpack ${A}
	cd "${S}"
	EPATCH_SUFFIX="patch" epatch "${FILESDIR}"/${PV}
	intltoolize --force --copy --automake || die "intltoolize failed."
	AT_M4DIR="/usr/share/xfce4/dev-tools/m4macros" eautoreconf
}

src_compile() {
	econf --disable-dependency-tracking \
		--enable-gradient-look \
		$(use_enable debug) \
		$(use_enable xfce mcs-plugin)
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}