1 files changed, 55 insertions, 0 deletions
diff --git a/net-im/openfetion/openfetion-2.1.0.ebuild b/net-im/openfetion/openfetion-2.1.0.ebuild
new file mode 100644
index 0000000..495f17e
--- /dev/null
+++ b/net-im/openfetion/openfetion-2.1.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit cmake-utils
+
+DESCRIPTION="A GTK IM client using CHINA MOBILE's Fetion Protocol 4"
+HOMEPAGE="http://ofetion.googlecode.com"
+SRC_URI="${HOMEPAGE}/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gstreamer libnotify networkmanager nls +xscreensaver"
+RESTRICT="mirror"
+
+DEPEND="gstreamer? ( media-libs/gstreamer )
+	libnotify? ( x11-libs/libnotify )
+	networkmanager? ( net-misc/networkmanager )
+	xscreensaver? ( x11-libs/libXScrnSaver )
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/libxml2
+	dev-libs/openssl
+	x11-libs/gtk+:2
+	x11-libs/gdk-pixbuf:2"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_disable nls)
+		$(cmake-utils_use_with libnotify)
+		$(cmake-utils_use_with gstreamer)
+		$(cmake-utils_use_with xscreensaver LIBXSS)
+		$(cmake-utils_use_with networkmanager)
+		$(cmake-utils_use_with networkmanager DBUSGLIB)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use gstreamer || rm "${D}/usr/share/openfetion/resource/newmessage.wav"
+}
+
+pkg_postinst() {
+	if ! use gstreamer; then
+		elog ""
+		elog "To use the sound reminder function, please enable gstreamer USE flag"
+		elog "and compile it again."
+		elog ""
+	fi
+}