1 files changed, 66 insertions, 0 deletions
diff --git a/media-sound/qmmp/qmmp-0.2.3.ebuild b/media-sound/qmmp/qmmp-0.2.3.ebuild
new file mode 100644
index 0000000..0e65a86
--- /dev/null
+++ b/media-sound/qmmp/qmmp-0.2.3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="1"
+
+inherit cmake-utils
+
+DESCRIPTION="Winamp-like audio player written with Qt4"
+HOMEPAGE="http://qmmp.ylsoftware.com/"
+SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="+alsa dbus +ffmpeg flac jack +libsamplerate mad modplug musepack oss
+pulseaudio +scrobbler sndfile +vorbis wavpack"
+
+RDEPEND="|| ( x11-libs/qt-gui =x11-libs/qt-4.3.0:4 )
+	media-libs/taglib
+	alsa? ( media-libs/alsa-lib )
+	dbus? ( sys-apps/dbus )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	musepack? ( >=media-libs/libmpcdec-1.2.5 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	wavpack? ( media-sound/wavpack )"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD=1
+qmmp_use_enable() {
+	# uses completely non standard cmake options...
+	use ${2} && echo "-DUSE_${1}:BOOL=TRUE" || echo "-DUSE_${1}:BOOL=FALSE"
+}
+
+src_compile() {
+	local mycmakeargs="${mycmakeargs}
+		$(qmmp_use_enable ALSA alsa)
+		$(qmmp_use_enable DBUS dbus)
+		$(qmmp_use_enable FFMPEG ffmpeg)
+		$(qmmp_use_enable FLAC flac)
+		$(qmmp_use_enable JACK jack)
+		$(qmmp_use_enable MAD mad)
+		$(qmmp_use_enable MODPLUG modplug)
+		$(qmmp_use_enable MPC musepack)
+		$(qmmp_use_enable OSS oss)
+		$(qmmp_use_enable PULSE pulseaudio)
+		$(qmmp_use_enable SCROBBLER scrobbler)
+		$(qmmp_use_enable SNDFILE sndfile)
+		$(qmmp_use_enable SRC libsamplerate)
+		$(qmmp_use_enable VORBIS vorbis)
+		$(qmmp_use_enable WAVPACK wavpack)
+		"
+	cmake-utils_src_compile
+}
+