dev-db/mycli: PEP517, modernize

Signed-off-by: Michał Górny <mgorny@gentoo.org>

4 files changed, 87 insertions, 9 deletions

diff --git a/dev-db/mycli/Manifest b/dev-db/mycli/Manifest
index 43d3adb840bd..45e3f918e0a0 100644
--- a/dev-db/mycli/Manifest
+++ b/dev-db/mycli/Manifest
@@ -1,2 +1,3 @@
 DIST mycli-1.24.1.tar.gz 275983 BLAKE2B cc03ebd0f4de1fabbd1c186139aac04a50d01529190972cac63765a4d3e688e994c112d001489bf1dfb17541370e0c348a368d85a86b7eed335b775b96897765 SHA512 5f8ffb98fd285d2e556bef7cefdc77588983c0028c7c24084710633fb469ae3c5ab2232ca23e87406d44d87e503c113039e6884ec9efd603f45b3ab7ed7c0925
+DIST mycli-1.25.0.gh.tar.gz 277022 BLAKE2B eabb07003741bc041fcfc7be92beade5bdf0c19d0be00b1a98037d38b164043e5280254b9c8446254928253f6059c33ae9395df780a2f30c5d9cbebffe020895 SHA512 e20b1466f0f2bf81f0d65bd23f97eae6b0943029c89d9d45f84368abc5f12c3054c09a45c4daea47831a192417e2e5be7bcd6622ea518e57b68f975a028d3f79
 DIST mycli-1.25.0.tar.gz 277022 BLAKE2B eabb07003741bc041fcfc7be92beade5bdf0c19d0be00b1a98037d38b164043e5280254b9c8446254928253f6059c33ae9395df780a2f30c5d9cbebffe020895 SHA512 e20b1466f0f2bf81f0d65bd23f97eae6b0943029c89d9d45f84368abc5f12c3054c09a45c4daea47831a192417e2e5be7bcd6622ea518e57b68f975a028d3f79
diff --git a/dev-db/mycli/metadata.xml b/dev-db/mycli/metadata.xml
index 861bfdab0b30..a84dc1414504 100644
--- a/dev-db/mycli/metadata.xml
+++ b/dev-db/mycli/metadata.xml
@@ -7,6 +7,7 @@
 	</maintainer>
 	<upstream>
 		<remote-id type="github">dbcli/mycli</remote-id>
+		<remote-id type="pypi">mycli</remote-id>
 	</upstream>
 	<use>
 		<flag name="ssh">Add support for connection over SSH tunnel</flag>
diff --git a/dev-db/mycli/mycli-1.25.0-r1.ebuild b/dev-db/mycli/mycli-1.25.0-r1.ebuild
new file mode 100644
index 000000000000..7adb613b75a5
--- /dev/null
+++ b/dev-db/mycli/mycli-1.25.0-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=yes
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="CLI for MySQL Database with auto-completion and syntax highlighting"
+HOMEPAGE="
+	https://www.mycli.net/
+	https://github.com/dbcli/mycli/
+	https://pypi.org/project/mycli/
+"
+SRC_URI="
+	https://github.com/dbcli/mycli/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ssh"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cli_helpers-2.2.1[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		>=dev-python/configobj-5.0.6[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/prompt-toolkit-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/prompt-toolkit-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pyaes[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-0.9.2[${PYTHON_USEDEP}]
+		dev-python/pyperclip[${PYTHON_USEDEP}]
+		>=dev-python/sqlparse-0.3.0[${PYTHON_USEDEP}]
+		<dev-python/sqlparse-0.5.0[${PYTHON_USEDEP}]
+		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )'
+	)
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/paramiko[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=( "${FILESDIR}/mycli-1.21.1-fix-test-install.patch" )
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		setup.py
+		mycli/magic.py
+		mycli/packages/parseutils.py
+		test/features
+		mycli/packages/paramiko_stub/__init__.py
+	)
+	epytest --capture=sys --doctest-modules --doctest-ignore-import-errors
+}
diff --git a/dev-db/mycli/mycli-9999.ebuild b/dev-db/mycli/mycli-9999.ebuild
index 878ff8604470..ede861eeb297 100644
--- a/dev-db/mycli/mycli-9999.ebuild
+++ b/dev-db/mycli/mycli-9999.ebuild
@@ -1,15 +1,21 @@
 # Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-PYTHON_COMPAT=( python3_{9..10} )
 DISTUTILS_SINGLE_IMPL=yes
-EGIT_REPO_URI="https://github.com/dbcli/mycli.git"
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..10} )
+
 inherit distutils-r1 git-r3
 
 DESCRIPTION="CLI for MySQL Database with auto-completion and syntax highlighting"
-HOMEPAGE="https://www.mycli.net"
+HOMEPAGE="
+	https://www.mycli.net/
+	https://github.com/dbcli/mycli/
+	https://pypi.org/project/mycli/
+"
+EGIT_REPO_URI="https://github.com/dbcli/mycli.git"
 
 LICENSE="BSD MIT"
 SLOT="0"
@@ -29,13 +35,16 @@ RDEPEND="
 		dev-python/pyperclip[${PYTHON_USEDEP}]
 		>=dev-python/sqlparse-0.3.0[${PYTHON_USEDEP}]
 		<dev-python/sqlparse-0.5.0[${PYTHON_USEDEP}]
-		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )')
+		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )'
+	)
 "
 BDEPEND="
-	test? ( $(python_gen_cond_dep '
-		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/paramiko[${PYTHON_USEDEP}]
-	') )
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/paramiko[${PYTHON_USEDEP}]
+		')
+	)
 "
 
 distutils_enable_tests pytest