dev-perl/ExtUtils-CppGuess: Bump to version 0.210.0

- Add bodge to src_test to avoid the problems with g++ autoprobe being
  broken with USE="-native-symlinks" for {gcc,binutils}-config, but
  runtime code is possibly broken on some targets :(. See:
   https://github.com/tsee/extutils-cppguess/issues/23

Upstream:
- Add ->iostream_fname, ->cpp_flavour_defs
- pass 'actual' compiler to MB/EUMM generated flags
- Support sun compiler family
- Improve clang detection
- Don't link to -lstdc++ if -static-libstdc++

Package-Manager: Portage-2.3.103, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-perl/ExtUtils-CppGuess/ExtUtils-CppGuess-0.210.0.ebuild b/dev-perl/ExtUtils-CppGuess/ExtUtils-CppGuess-0.210.0.ebuild
new file mode 100644
index 000000000000..feea25b4a034
--- /dev/null
+++ b/dev-perl/ExtUtils-CppGuess/ExtUtils-CppGuess-0.210.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=ETJ
+DIST_VERSION=0.21
+inherit perl-module toolchain-funcs
+
+DESCRIPTION="Guess C++ compiler and flags"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-perl/Capture-Tiny
+	>=virtual/perl-ExtUtils-ParseXS-3.350.0
+	virtual/perl-File-Spec
+	virtual/perl-File-Temp
+"
+BDEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	test? (
+		virtual/perl-File-Path
+		virtual/perl-Data-Dumper
+		>=virtual/perl-ExtUtils-CBuilder-0.280.231
+		virtual/perl-ExtUtils-Manifest
+		dev-perl/Module-Build
+		>=virtual/perl-Test-Simple-0.880.0
+		virtual/perl-autodie
+	)
+"
+src_test() {
+	# https://github.com/tsee/extutils-cppguess/issues/23
+	tc-export CXX
+	mkdir -p "${T}/bin" || die "Cant make dir ${T}/bin"
+	einfo "CXX: ${CXX}"
+	ln -vs "${EPREFIX}/usr/bin/${CXX}" "${T}/bin/g++" || die "Can't make symlink ${T}/bin/g++"
+	PATH="${T}/bin:${PATH}" perl-module_src_test
+}