dev-python/colander: Bump

Package-Manager: portage-2.2.27

2 files changed, 58 insertions, 0 deletions

diff --git a/dev-python/colander/Manifest b/dev-python/colander/Manifest
index 7e61f3280592..45cce47d0d3c 100644
--- a/dev-python/colander/Manifest
+++ b/dev-python/colander/Manifest
@@ -1 +1,2 @@
 DIST colander-1.0.tar.gz 113800 SHA256 7389413266b9e680c9529c16d56284edf87e0d5de557948e75f41d65683c23b3 SHA512 f361520a12ebec4271580fe5be002bfbdd38fcd4cfb29fa41b9c37308636343dd25595f2e0bd8099bc96583d25644d2039996efefd9c0060fe39f3c46394a4f7 WHIRLPOOL c1ed492781ab276fc5c6cf7d0ce6a9393981c86ed06c9b113c2e37e01748595e8b5422fa24eaac3d3c2a68cd99f337ea9c65b8f0f536f955e2b9b621101278a5
+DIST colander-1.2.tar.gz 117130 SHA256 528f406cd1bf65cfd08958c9c8b839f37e96a65696a8f213ce81a59aae33dae4 SHA512 09bea3b0b4d2a5bd9539d36d0c43fe0d4042fd945d2e74a01c2c9639d19175f73356f006e69a22765ebffeb01310de7e73ee165826081afa14a46e1cd93995a4 WHIRLPOOL 372ad6050f017f534cd3cdaa3a499e766582da5346627517b8f05f080e3aff215f0363440fd0d7e1fb3f1d5855338aab347bbf757c70a7ca0978928fd027f219
diff --git a/dev-python/colander/colander-1.2.ebuild b/dev-python/colander/colander-1.2.ebuild
new file mode 100644
index 000000000000..c83a3589ff12
--- /dev/null
+++ b/dev-python/colander/colander-1.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A simple schema-based serialization and deserialization library"
+HOMEPAGE="http://docs.pylonsproject.org/projects/colander/en/latest/ https://pypi.python.org/pypi/colander"
+MY_P=${P/_beta1/b1}
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+# MIT license is used by included (modified) iso8601.py code.
+LICENSE="repoze MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+# Depend on an ebuild of translationstring with Python 3 support.
+RDEPEND=">=dev-python/translationstring-1.1[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/iso8601[${PYTHON_USEDEP}] )"
+
+# Include COPYRIGHT.txt because the license seems to require it.
+DOCS=( CHANGES.rst COPYRIGHT.txt README.rst )
+
+python_prepare_all() {
+	# Remove pylons theme since it's not included in source
+	sed -e "/# Add and use Pylons theme/,+37d" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		# https://github.com/Pylons/colander/issues/38
+		emake -C docs html SPHINXOPTS=""
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}