dev-python/notebook: Bump to 6.4.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 100 insertions, 0 deletions

diff --git a/dev-python/notebook/Manifest b/dev-python/notebook/Manifest
index 05de332e9d10..b1aa7f228fd7 100644
--- a/dev-python/notebook/Manifest
+++ b/dev-python/notebook/Manifest
@@ -1 +1,2 @@
 DIST notebook-6.3.0.tar.gz 13922153 BLAKE2B f24b03d4887b1e786da215a4ab10d83e4ae8391d1b88559f4bb35fcf7813d98e487447bf21a1772d502d6b3594c53e6e7b743b681cdb07b5118cc4808bcd02a4 SHA512 112bb0b176f7e6584ca0f09d74cb34fe756d0491320dcc23932f84236fd55b9f56f13a7057c89be073486637fc8c0cf2c44dfce18f27fa16ad0f9d15d2bcd5be
+DIST notebook-6.4.0.tar.gz 13937270 BLAKE2B 41ba6e3dd22c92b6044199737fe93563aad07117e8c64817566765d643867b582218a1b34099acf2a84df9ac9f8eb2773f6f3e6779b14255867fd97ec443df85 SHA512 8bb57b3efaaddb781ee963a569996e45c563b50b2cb918fb7722805710dd5852d895ff5b5f5575686032a037d7395aa581140b471b529d68dfcb371841607481
diff --git a/dev-python/notebook/notebook-6.4.0.ebuild b/dev-python/notebook/notebook-6.4.0.ebuild
new file mode 100644
index 000000000000..9de1aeb1b611
--- /dev/null
+++ b/dev-python/notebook/notebook-6.4.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-libs/mathjax-2.4
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.2.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-5.3.4[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.2.0[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]"
+
+# sphinx 2+ seems to have a problem with its github plugin. temporarily adding
+# a version constraint.
+BDEPEND="
+	test? (
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}"-5.7.0-no-mathjax.patch
+)
+
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# disable bundled mathjax
+	sed -i 's/^.*MathJax.*$//' bower.json || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local deselect=(
+		# trash doesn't seem to work for us
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_checkpoints_follow_file
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_dirs
+		notebook/services/contents/tests/test_contents_api.py::GenericFileCheckpointsAPITest::test_delete_non_empty_dir
+		notebook/services/contents/tests/test_manager.py::TestContentsManager::test_delete
+		notebook/services/contents/tests/test_manager.py::TestContentsManagerNoAtomic::test_delete
+		# TODO
+		notebook/services/kernels/tests/test_kernels_api.py::KernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::AsyncKernelAPITest::test_connections
+		notebook/services/kernels/tests/test_kernels_api.py::KernelCullingTest::test_culling
+	)
+
+	# selenium tests require geckodriver
+	epytest --ignore notebook/tests/selenium ${deselect[@]/#/--deselect }
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	ln -sf \
+		"${EPREFIX}/usr/share/mathjax" \
+		"${D}$(python_get_sitedir)/notebook/static/components/MathJax" || die
+}
+
+pkg_preinst() {
+	# remove old mathjax folder if present
+	rm -rf "${EROOT}"/usr/lib*/python*/site-packages/notebook/static/components/MathJax || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}