dev-python/pdm: Bump to 2.8.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index 7806eda5507d..eb340ee8f308 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
 DIST pdm-2.8.0.tar.gz 3069029 BLAKE2B 3fc3246c7bf26953be96def58d8249c981def96e1607b82b35f1b8347dc5246dd6b4613e4f2093e2e6453724e8709951d2fff38a1f02f2dcc5e85fe6e8c678da SHA512 95cc0a4cb032fa39281aea5ab2f31da7f503c6444a9c41d88ac9bf9ab650654a3f154506f2ed822e70266046c4b6a111518ed68aa7ab75aa31c096e071859bcd
+DIST pdm-2.8.1.tar.gz 3014347 BLAKE2B 0dde8e2376065ac6241e06c24a7b1b241e5653f6e2cb7fd529cc8dfd3d0f6c6fc4c6a43208551594a7d837d11dbaff02612d944a9077cb132d3eee3c23559ee7 SHA512 f18fddd533cf0b72f9ff376c865bc5df6a58c248f4c9737404eb1d62f5d9a233f22b7a76db3b2f9b7a321c8d1e3aa2ea395d2dd3ffe29834ccc09c8272410b82
diff --git a/dev-python/pdm/pdm-2.8.1.ebuild b/dev-python/pdm/pdm-2.8.1.ebuild
new file mode 100644
index 000000000000..281812e00468
--- /dev/null
+++ b/dev-python/pdm/pdm-2.8.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.10.0[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/tomli[${PYTHON_USEDEP}]' pypy3 python3_10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/cli/test_build.py::test_build_with_no_isolation[False]'
+		tests/test_project.py::test_access_index_with_auth
+		tests/cli/test_others.py::test_build_distributions
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[-e file:///${PROJECT_ROOT}/tests/fixtures/projects/demo-#-with-hash#egg=demo]'
+		# hangs on interactive keyring prompts
+		tests/cli/test_config.py::test_repository_overwrite_default
+		tests/cli/test_config.py::test_hide_password_in_output_repository
+		tests/cli/test_config.py::test_hide_password_in_output_pypi
+		# junk output, sigh
+		tests/cli/test_others.py::test_info_command_json
+		# why does it try to use python 2.7?!
+		tests/cli/test_run.py::test_import_another_sitecustomize
+	)
+
+	epytest -m "not network and not integration and not path"
+}