dev-util/astyle: version bump to 2.05.1 (bug #530584)

This commit also updates the soname handling (no trailing .0 in soname any
more).

Special thanks to David Hallas for an initial ebuild update.

Gentoo-Bug: 530584

Package-Manager: portage-2.2.20.1

1 files changed, 67 insertions, 0 deletions

diff --git a/dev-util/astyle/astyle-2.04-r1.ebuild b/dev-util/astyle/astyle-2.04-r1.ebuild
new file mode 100644
index 000000000000..3ac6b57bc829
--- /dev/null
+++ b/dev-util/astyle/astyle-2.04-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils java-pkg-opt-2 multilib toolchain-funcs
+
+DESCRIPTION="Artistic Style is a reindenter and reformatter of C++, C and Java source code"
+HOMEPAGE="http://astyle.sourceforge.net/"
+SRC_URI="mirror://sourceforge/astyle/astyle_${PV}_linux.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+
+IUSE="doc java static-libs"
+
+DEPEND="app-arch/xz-utils
+	java? ( >=virtual/jdk-1.6:= )"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+	tc-export CXX
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.02.1-build_system.patch
+	java-pkg-opt-2_src_prepare
+	sed	-e "s:^\(JAVAINCS\s*\)=.*$:\1= $(java-pkg_get-jni-cflags):" \
+		-e "s:ar crs:$(tc-getAR) crs:" \
+		-i build/gcc/Makefile || die
+}
+
+src_compile() {
+	emake -f ../build/gcc/Makefile -C src \
+		${PN} \
+		shared \
+		$(usex java java '') \
+		$(usex static-libs static '')
+}
+
+src_install() {
+	insinto /usr/include
+	doins src/${PN}.h
+
+	pushd src/bin &> /dev/null
+	dobin ${PN}
+
+	dolib.so lib${PN}.so.0.0.0
+	dosym lib${PN}.so.0.0.0 /usr/$(get_libdir)/lib${PN}.so.0
+	dosym lib${PN}.so.0.0.0 /usr/$(get_libdir)/lib${PN}.so
+	if use java ; then
+		dolib.so lib${PN}j.so.0.0.0
+		dosym lib${PN}j.so.0.0.0 /usr/$(get_libdir)/lib${PN}j.so.0
+		dosym lib${PN}j.so.0.0.0 /usr/$(get_libdir)/lib${PN}j.so
+	fi
+	if use static-libs ; then
+		dolib lib${PN}.a
+	fi
+	popd &> /dev/null
+
+	use doc && dohtml doc/*
+}