dev-util/include-what-you-use: bump up to 12.0

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-util/include-what-you-use/Manifest b/dev-util/include-what-you-use/Manifest
index 03e0eed13751..76cb95843f4e 100644
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1 +1,2 @@
 DIST include-what-you-use-11.0.tar.gz 603435 BLAKE2B 7bfa37349cc4bf5d07033c28d9d3851f0ce2093f1703a0392ac633ab2761dfdfb7cd923099177747e3389d2d41330351242c6f936399acf73119c201d8776978 SHA512 db15efa9b92015322e9a188be6cf16a5c6fd71271c94fde45245676f2a8f6ffe4c7837e3b0bb5f9be6cbe78aab245129816a3b046c44c261a2b7ab5c3a9ea7b9
+DIST include-what-you-use-12.0.tar.gz 742573 BLAKE2B b8cd90db490d13f140126df8955d0968a9248480da09ca29b82fe1178c779ca75e6f29239bc6fb1556200c7d7c498f2340839e8500455ecaed9e6199fd3d55f7 SHA512 2923e18c40ddc5c03458b896d991adde03d489c6645ecc3cc4f69a508e323534afdef3233943e99533ffc21c64a10a8a5c635dc4797a61edf09d0a7a918a3cd5
diff --git a/dev-util/include-what-you-use/include-what-you-use-12.0.ebuild b/dev-util/include-what-you-use/include-what-you-use-12.0.ebuild
new file mode 100644
index 000000000000..ecd93d6af5f9
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-12.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit cmake flag-o-matic llvm python-single-r1
+
+# Sometimes the tag is clang_9, sometimes it's IWYU-0.13
+UPSTREAM_PV=0.16
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${UPSTREAM_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=12
+
+RDEPEND="
+	sys-devel/clang:${LLVM_MAX_SLOT}=
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${PN}-${UPSTREAM_PV}
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py
+}