kde-plasma/plasma-meta: 6.0.1 version bump

See also:
https://kde.org/announcements/changelogs/plasma/6/6.0.0-6.0.1/

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 120 insertions, 0 deletions

diff --git a/kde-plasma/plasma-meta/metadata.xml b/kde-plasma/plasma-meta/metadata.xml
index 739e05ae62ee..715252bddc69 100644
--- a/kde-plasma/plasma-meta/metadata.xml
+++ b/kde-plasma/plasma-meta/metadata.xml
@@ -22,13 +22,16 @@
 		<flag name="gtk">Enable Breeze widget style and system settings module for GTK+</flag>
 		<flag name="kwallet">Enable support for KWallet auto-unlocking via <pkg>kde-plasma/kwallet-pam</pkg></flag>
 		<flag name="legacy-systray">Add support for legacy applications using <pkg>kde-plasma/xembed-sni-proxy</pkg></flag>
+		<flag name="oxygen-theme">Pull in Oxygen icons, sound theme and visual style for KDE Plasma</flag>
 		<flag name="plymouth">Pull in Breeze theme for <pkg>sys-boot/plymouth</pkg></flag>
 		<flag name="pulseaudio">Install Plasma applet for PulseAudio volume management</flag>
 		<flag name="sddm">Pull in the <pkg>x11-misc/sddm</pkg> display manager and system settings module</flag>
 		<flag name="sdk">Pull in <pkg>kde-plasma/plasma-sdk</pkg> for Plasma development</flag>
 		<flag name="smart">Pull in <pkg>kde-plasma/plasma-disks</pkg> for disk health monitoring</flag>
 		<flag name="thunderbolt">Pull in <pkg>kde-plasma/plasma-thunderbolt</pkg> control center module</flag>
+		<flag name="unsupported">Allow packages that are known to ruin runtime experience ** DO NOT FILE BUGS WITH THIS ENABLED **</flag>
 		<flag name="wacom">Pull in <pkg>kde-plasma/wacomtablet</pkg> control center module</flag>
 		<flag name="wallpapers">Install wallpapers for the Plasma Workspace</flag>
+		<flag name="xwayland">Enable Wayland windows screensharing to XWayland applications via <pkg>gui-apps/xwaylandvideobridge</pkg></flag>
 	</use>
 </pkgmetadata>
diff --git a/kde-plasma/plasma-meta/plasma-meta-6.0.1.ebuild b/kde-plasma/plasma-meta/plasma-meta-6.0.1.ebuild
new file mode 100644
index 000000000000..cbd2949a4727
--- /dev/null
+++ b/kde-plasma/plasma-meta/plasma-meta-6.0.1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Merge this to pull in all Plasma 6 packages"
+HOMEPAGE="https://kde.org/plasma-desktop/"
+
+LICENSE="metapackage"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="accessibility bluetooth +browser-integration colord +crash-handler crypt
+cups discover +display-manager +elogind +firewall flatpak grub gtk +handbook
++kwallet +networkmanager oxygen-theme plymouth pulseaudio +sddm sdk +smart
+systemd thunderbolt unsupported wacom +wallpapers +xwayland"
+
+REQUIRED_USE="^^ ( elogind systemd )"
+
+RDEPEND="
+	!${CATEGORY}/${PN}:5
+	>=kde-plasma/breeze-${PV}:${SLOT}
+	>=kde-plasma/kactivitymanagerd-${PV}:${SLOT}
+	>=kde-plasma/kde-cli-tools-${PV}:${SLOT}
+	>=kde-plasma/kdecoration-${PV}:${SLOT}
+	>=kde-plasma/kdeplasma-addons-${PV}:${SLOT}
+	>=kde-plasma/kgamma-${PV}:${SLOT}
+	>=kde-plasma/kglobalacceld-${PV}:${SLOT}
+	>=kde-plasma/kinfocenter-${PV}:${SLOT}
+	>=kde-plasma/kmenuedit-${PV}:${SLOT}
+	>=kde-plasma/kpipewire-${PV}:${SLOT}
+	>=kde-plasma/kscreen-${PV}:${SLOT}
+	>=kde-plasma/kscreenlocker-${PV}:${SLOT}
+	>=kde-plasma/ksshaskpass-${PV}:${SLOT}
+	>=kde-plasma/ksystemstats-${PV}:${SLOT}
+	>=kde-plasma/kwayland-${PV}:${SLOT}
+	>=kde-plasma/kwayland-integration-${PV}:5
+	>=kde-plasma/kwin-${PV}:${SLOT}[lock]
+	>=kde-plasma/kwrited-${PV}:${SLOT}
+	>=kde-plasma/layer-shell-qt-${PV}:${SLOT}
+	>=kde-plasma/libkscreen-${PV}:${SLOT}
+	>=kde-plasma/libksysguard-${PV}:${SLOT}
+	>=kde-plasma/libplasma-${PV}:${SLOT}
+	>=kde-plasma/milou-${PV}:${SLOT}
+	>=kde-plasma/ocean-sound-theme-${PV}:${SLOT}
+	>=kde-plasma/plasma-activities-${PV}:${SLOT}
+	>=kde-plasma/plasma-activities-stats-${PV}:${SLOT}
+	>=kde-plasma/plasma-desktop-${PV}:${SLOT}
+	>=kde-plasma/plasma-integration-${PV}:${SLOT}
+	>=kde-plasma/plasma-systemmonitor-${PV}:${SLOT}
+	>=kde-plasma/plasma-welcome-${PV}:${SLOT}
+	>=kde-plasma/plasma-workspace-${PV}:${SLOT}
+	>=kde-plasma/plasma5support-${PV}:${SLOT}
+	>=kde-plasma/polkit-kde-agent-${PV}:*
+	>=kde-plasma/powerdevil-${PV}:${SLOT}
+	>=kde-plasma/qqc2-breeze-style-${PV}:${SLOT}
+	>=kde-plasma/systemsettings-${PV}:${SLOT}
+	>=kde-plasma/xdg-desktop-portal-kde-${PV}:${SLOT}
+	sys-apps/dbus[elogind?,systemd?]
+	sys-auth/polkit[systemd?]
+	sys-fs/udisks:2[elogind?,systemd?]
+	bluetooth? ( >=kde-plasma/bluedevil-${PV}:${SLOT} )
+	browser-integration? ( >=kde-plasma/plasma-browser-integration-${PV}:${SLOT} )
+	colord? ( x11-misc/colord )
+	crash-handler? ( >=kde-plasma/drkonqi-${PV}:${SLOT} )
+	crypt? ( >=kde-plasma/plasma-vault-${PV}:${SLOT} )
+	cups? ( >=kde-plasma/print-manager-${PV}:${SLOT} )
+	discover? ( >=kde-plasma/discover-${PV}:${SLOT} )
+	display-manager? (
+		sddm? (
+			>=kde-plasma/sddm-kcm-${PV}:${SLOT}
+			x11-misc/sddm[elogind?,systemd?]
+		)
+		!sddm? ( x11-misc/lightdm )
+	)
+	elogind? ( sys-auth/elogind[pam] )
+	flatpak? ( >=kde-plasma/flatpak-kcm-${PV}:${SLOT} )
+	grub? ( >=kde-plasma/breeze-grub-${PV}:${SLOT} )
+	gtk? (
+		>=kde-plasma/breeze-gtk-${PV}:${SLOT}
+		>=kde-plasma/kde-gtk-config-${PV}:${SLOT}
+		x11-misc/appmenu-gtk-module
+	)
+	handbook? ( kde-apps/khelpcenter:* )
+	kwallet? ( >=kde-plasma/kwallet-pam-${PV}:${SLOT} )
+	networkmanager? (
+		>=kde-plasma/plasma-nm-${PV}:${SLOT}
+		net-misc/networkmanager[elogind?,systemd?]
+	)
+	oxygen-theme? (
+		>=kde-frameworks/oxygen-icons-6.0.0:*
+		>=kde-plasma/oxygen-${PV}:${SLOT}
+		>=kde-plasma/oxygen-sounds-${PV}:${SLOT}
+	)
+	plymouth? (
+		>=kde-plasma/breeze-plymouth-${PV}:${SLOT}
+		>=kde-plasma/plymouth-kcm-${PV}:${SLOT}
+	)
+	pulseaudio? ( >=kde-plasma/plasma-pa-${PV}:${SLOT} )
+	sdk? ( >=kde-plasma/plasma-sdk-${PV}:${SLOT} )
+	smart? ( >=kde-plasma/plasma-disks-${PV}:${SLOT} )
+	systemd? (
+		sys-apps/systemd[pam]
+		firewall? ( >=kde-plasma/plasma-firewall-${PV}:${SLOT} )
+	)
+	thunderbolt? ( >=kde-plasma/plasma-thunderbolt-${PV}:${SLOT} )
+	!unsupported? (
+		!gui-apps/qt6ct
+		!sys-apps/xdg-desktop-portal-gnome
+	)
+	wacom? ( >=kde-plasma/wacomtablet-${PV}:${SLOT} )
+	wallpapers? ( >=kde-plasma/plasma-workspace-wallpapers-${PV}:${SLOT} )
+	xwayland? ( >=gui-apps/xwaylandvideobridge-0.4.0 )
+"
+# Optional runtime deps: kde-plasma/plasma-desktop
+RDEPEND="${RDEPEND}
+	accessibility? ( app-accessibility/orca )
+"