media-gfx/gimp: 2.10.8

Also sync 9999 and back from dependency media-libs/libmypaint[gegl]
down to plain media-libs/libmypaint.
Closes: https://bugs.gentoo.org/670990
Closes: https://bugs.gentoo.org/671170
Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

3 files changed, 230 insertions, 4 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index 3c3570948e1e..7f2f07a1a781 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -1,5 +1,6 @@
 DIST gimp-2.10.2.tar.bz2 30863771 BLAKE2B a3525f7266ffe35be1daf973bee4ea107d9e7384e0c85a792f2fc69bd29fa8ee3d19409586b9b1e1bf36a1be4e30719c7ed945e5de9b7cb4be4f81be06ea1468 SHA512 6e351294e018a9f879993700355bdf5f10bccc6862604ae1950c4d235d32cdfcd6a0195b37377819adeef53ab3d24f32ed1de60cba6bafe58608ed0906a6fbcf
 DIST gimp-2.10.4.tar.bz2 31064613 BLAKE2B 66d815c830696923759146dce68049131078ddf4f67242c78a7755db34c1b7e31b1b25bfe52e8e47a7fb81e24e60e4161261043484242c4682ca6cf362d55816 SHA512 9d0cc8d97b82423687b579907edaab6044f19a8207426edf4f7428de23fa82481112bb0a53b06bb7037b68d92336517b1eddef4600519707e7feedb64e5414f7
 DIST gimp-2.10.6.tar.bz2 31447973 BLAKE2B 96df16c1d774726580ad09317cba31f36bac341aa53178bdb04444c87406465b2c56d508ba0b8c012ad8abc85136f8c635b6e9875e4da57c97e6a6832edbc296 SHA512 1330ec756ec5f57243435e66aeb5f6214a9783e26763be6679714010a631e47dbb8b5f610195587af29261d2183332a4a4c6202acafc3f2837ae7a6b7f9a30c2
+DIST gimp-2.10.8.tar.bz2 31954568 BLAKE2B 11f88b1068fa1fe216a54bed27b26b94c3fdb2cbc67e1e444df74a080d00b678f8c81897a6c5fb5956fa107842b0a853ada44d15d51c2e58db7435ddd0f8e999 SHA512 b458dd710b786152f95a8e48a0727b71cac549fccb31ac9e1e6ac3c617652079773ce7076401f8ade750ed38bdc78dfdec3317423f4c4e9c931f78002bd7454e
 DIST gimp-2.8.22.tar.bz2 20873278 BLAKE2B 673246fd2354f1cecc74bf389df698f594b7553cc88a1d2679ae410ad39923abae843dfe9623ec195b4f967b5eccd199769a6300bf028ae04b8df4932df11505 SHA512 84a78d428282538b606b3cd1ff571e52c3d828fceade171b2012bc1cdcb85919fc7734e7e6c45ed3a8683657fa580412b32c1b511b8a512172a8c1df930493e6
 DIST gimp-2.9.8.tar.bz2 26161474 BLAKE2B f00a58d33848a818a2cb3b74920b33156330a26423a2b567cd8372258f87b44ae1ad812f2b3ee9a093b919d022e8b71ef518d40b76ab94c616f9916b3d1effec SHA512 897092aa823961e6ed5dac47eaadd3a25c419364d6ca791987d99e495d0d4eba1d75e08c809dfa305e8feec9da606193b608e3470e0ef18fcfaa98ee8aedfe02
diff --git a/media-gfx/gimp/gimp-2.10.8.ebuild b/media-gfx/gimp/gimp-2.10.8.ebuild
new file mode 100644
index 000000000000..319f017de166
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.10.8.ebuild
@@ -0,0 +1,222 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+GNOME2_EAUTORECONF=yes
+
+MY_PV="${PV/_rc/-RC}"
+MY_P="${PN}-${MY_PV}"
+
+inherit versionator virtualx autotools gnome2 multilib python-single-r1 ltprune
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+
+LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
+IUSE="alsa aalib altivec aqua debug doc openexr gnome heif postscript jpeg2k cpu_flags_x86_mmx mng python smp cpu_flags_x86_sse udev unwind vector-icons webp wmf xpm"
+
+RDEPEND=">=dev-libs/glib-2.56.0:2
+	>=dev-libs/atk-2.2.0
+	>=x11-libs/gtk+-2.24.10:2
+	>=x11-libs/gdk-pixbuf-2.31:2
+	>=x11-libs/cairo-1.12.2
+	>=x11-libs/pango-1.29.4
+	xpm? ( x11-libs/libXpm )
+	>=media-libs/freetype-2.1.7
+	>=media-libs/harfbuzz-0.9.19
+	>=media-libs/gexiv2-0.10.6
+	>=media-libs/libmypaint-1.3.0
+	>=media-gfx/mypaint-brushes-1.3.0
+	>=media-libs/fontconfig-2.12.4
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-themes/hicolor-icon-theme
+	>=media-libs/babl-0.1.58
+	>=media-libs/gegl-0.4.12:0.4[cairo]
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	aqua? ( x11-libs/gtk-mac-integration )
+	gnome? ( gnome-base/gvfs )
+	virtual/jpeg:0
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
+	>=media-libs/lcms-2.8:2
+	mng? ( media-libs/libmng )
+	openexr? ( >=media-libs/openexr-1.6.1:= )
+	>=app-text/poppler-0.44[cairo]
+	>=app-text/poppler-data-0.4.7
+	>=media-libs/libpng-1.6.25:0=
+	python?	(
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2.10.4:2[${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.0.2[${PYTHON_USEDEP}]
+	)
+	>=media-libs/tiff-3.5.7:0
+	>=gnome-base/librsvg-2.40.6:2
+	webp? ( >=media-libs/libwebp-0.6.0 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	net-libs/glib-networking[ssl]
+	x11-libs/libXcursor
+	sys-libs/zlib
+	app-arch/bzip2
+	>=app-arch/xz-utils-5.0.0
+	postscript? ( app-text/ghostscript-gpl )
+	udev? ( virtual/libgudev:= )
+	unwind? ( sys-libs/libunwind:= )
+	heif? ( >=media-libs/libheif-1.1.0:= )"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5.10.0
+	dev-libs/appstream-glib
+	dev-util/gtk-update-icon-cache
+	sys-apps/findutils
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.19
+	doc? ( >=dev-util/gtk-doc-1 )
+	>=sys-devel/libtool-2.2
+	>=sys-devel/automake-1.11
+	dev-util/gtk-doc-am"
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
+	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+
+	gnome2_src_prepare  # calls eautoreconf
+
+	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
+	fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+}
+
+src_configure() {
+	local myconf=(
+		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
+		GDBUS_CODEGEN="${EPREFIX}"/bin/false
+
+		--enable-default-binary
+		--disable-silent-rules
+
+		$(use_with !aqua x)
+		$(use_with aalib aa)
+		$(use_with alsa)
+		$(use_enable altivec)
+		--with-appdata-test
+		--without-libbacktrace
+		--with-bug-report-url=https://bugs.gentoo.org/
+		--without-webkit
+		$(use_with jpeg2k jpeg2000)
+		$(use_with postscript gs)
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_with mng libmng)
+		$(use_with openexr)
+		$(use_with webp)
+		$(use_with heif libheif)
+		$(use_enable python)
+		$(use_enable smp mp)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_with udev gudev)
+		$(use_with unwind)
+		$(use_with wmf)
+		--with-xmc
+		$(use_with xpm libxpm)
+		$(use_enable vector-icons)
+		--without-xvfb-run
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+	addwrite /dev/dri/  # bug #574038
+	addwrite /dev/ati/  # bug 589198
+	addwrite /proc/mtrr  # bug 589198
+
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	gnome2_src_compile
+}
+
+_clean_up_locales() {
+	[[ -z ${LINGUAS+set} ]] && return
+	einfo "Cleaning up locales..."
+	for lang in ${LANGS}; do
+		has ${lang} ${LINGUAS} && {
+			einfo "- keeping ${lang}"
+			continue
+		}
+		rm -Rf "${ED%/}"/usr/share/locale/"${lang}"
+	done
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prepend=gimp-org-
+	(
+		cd "${ED%/}"/usr/$(get_libdir)/gimp/2.0/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+		    plugin=${plugin_slash%/}
+		    if [[ -f ${plugin}/${plugin} ]]; then
+			# NOTE: Folder and file name need to match for Gimp to load that plug-in
+			#       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
+			mv ${plugin}/{,${prepend}}${plugin} || exit 1
+			mv {,${prepend}}${plugin} || exit 1
+		    fi
+		done
+	)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED%/}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	prune_libtool_files --all
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	local gimp_app_version=$(get_version_component_range 1-2)
+	mv "${ED%/}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
+	_rename_plugins || die
+	_clean_up_locales
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}
diff --git a/media-gfx/gimp/gimp-9999.ebuild b/media-gfx/gimp/gimp-9999.ebuild
index ac017892f38c..b4f7112177ad 100644
--- a/media-gfx/gimp/gimp-9999.ebuild
+++ b/media-gfx/gimp/gimp-9999.ebuild
@@ -16,7 +16,7 @@ SLOT="2"
 KEYWORDS=""
 
 LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
-IUSE="alsa aalib altivec aqua debug doc openexr gnome heif postscript jpeg2k cpu_flags_x86_mmx mng python smp cpu_flags_x86_sse udev vector-icons webp wmf xpm"
+IUSE="alsa aalib altivec aqua debug doc openexr gnome heif postscript jpeg2k cpu_flags_x86_mmx mng python smp cpu_flags_x86_sse udev unwind vector-icons webp wmf xpm"
 
 RDEPEND=">=dev-libs/glib-2.56.0:2
 	>=dev-libs/atk-2.2.0
@@ -28,15 +28,15 @@ RDEPEND=">=dev-libs/glib-2.56.0:2
 	>=media-libs/freetype-2.1.7
 	>=media-libs/harfbuzz-0.9.19
 	>=media-libs/gexiv2-0.10.6
-	>=media-libs/libmypaint-1.3.0[gegl]
+	>=media-libs/libmypaint-1.3.0
 	>=media-gfx/mypaint-brushes-1.3.0
 	>=media-libs/fontconfig-2.12.4
 	sys-libs/zlib
 	dev-libs/libxml2
 	dev-libs/libxslt
 	x11-themes/hicolor-icon-theme
-	>=media-libs/babl-0.1.56
-	>=media-libs/gegl-0.4.8:0.4[cairo]
+	>=media-libs/babl-0.1.58
+	>=media-libs/gegl-0.4.12:0.4[cairo]
 	aalib? ( media-libs/aalib )
 	alsa? ( media-libs/alsa-lib )
 	aqua? ( x11-libs/gtk-mac-integration )
@@ -65,6 +65,7 @@ RDEPEND=">=dev-libs/glib-2.56.0:2
 	>=app-arch/xz-utils-5.0.0
 	postscript? ( app-text/ghostscript-gpl )
 	udev? ( virtual/libgudev:= )
+	unwind? ( sys-libs/libunwind:= )
 	heif? ( >=media-libs/libheif-1.1.0:= )"
 DEPEND="${RDEPEND}
 	>=dev-lang/perl-5.10.0
@@ -114,6 +115,7 @@ src_configure() {
 		$(use_with alsa)
 		$(use_enable altivec)
 		--with-appdata-test
+		--without-libbacktrace
 		--with-bug-report-url=https://bugs.gentoo.org/
 		--without-webkit
 		$(use_with jpeg2k jpeg2000)
@@ -127,6 +129,7 @@ src_configure() {
 		$(use_enable smp mp)
 		$(use_enable cpu_flags_x86_sse sse)
 		$(use_with udev gudev)
+		$(use_with unwind)
 		$(use_with wmf)
 		--with-xmc
 		$(use_with xpm libxpm)