media-libs/libmediainfo: version bump to 17.10

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 314a947c4fbf..12ddcf863178 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1 +1,2 @@
 DIST libmediainfo_0.7.99.tar.xz 1603656 SHA256 ec9a8f2e081eefda05ddb841a3ffc838bf6ef8aedaf40f47fdbd19fd739fd688 SHA512 a0ceaf142604a98e9415ecfeda29d7c3d57ac755903630c2a5b2782d3bb24a101c46c93c68858dce99299da6375e03b846b5973274168ca8c42315b82a0cfdc0 WHIRLPOOL 06f197dc2292a90b92c5862f48d02df74d770d7e218f9e978e0d6ff081ce8a7970bab9c00ed6d01fdae0dc0868b031c20447abd6046efb6b6f1c6a60f81a9ac1
+DIST libmediainfo_17.10.tar.xz 1606920 SHA256 60b018fcd8acd249c5316670bdf1c85abc166fb9c340e84da834b1332a59a102 SHA512 3fe8b7c97c9b916376c090c89f7b5afb732d002d5d112370b977c83d9bea2911ec7cc249fa7df6f4b100600cc2354d6a8832339cf0d3b45262730a477c07fd4d WHIRLPOOL fa9a532a1ea49954c45eef80ea0cf5fe1c3e30ca4746b5a138aa396750c1b2f7bd4cbd4f7d7d44cb7027148baf41743e78462f7d6f448a0a357c09e7cfd39df2
diff --git a/media-libs/libmediainfo/libmediainfo-17.10.ebuild b/media-libs/libmediainfo/libmediainfo-17.10.ebuild
new file mode 100644
index 000000000000..7be3ed1e7919
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-17.10.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools ltprune flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfoLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.37[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	prune_libtool_files
+}