media-video/gaupol: replace USE flags with optfeature, update LICENSE

* Update LICENSE from GPL-2+ to GPL-3+.
* Replace elog messages with optfeature.
* Explicitly list mandatory GStreamer plugins.
* Replace USE=spell with better optfeature messages.
* Mention the newer USE=nuspell backend for enchant before USE=hunspell.
* Allow tests to run with enchant built with USE=nuspell.
* Remove GitHub from HOMEPAGE as it's already listed as an upstream in
  metadata.xml.

Signed-off-by: gentoo-setan <gentoo-setan@protonmail.com>
Signed-off-by: Louis Sautier <sbraz@gentoo.org>
Co-authored-by: Louis Sautier <sbraz@gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/37194

2 files changed, 74 insertions, 69 deletions

diff --git a/media-video/gaupol/gaupol-1.15-r1.ebuild b/media-video/gaupol/gaupol-1.15-r1.ebuild
new file mode 100644
index 000000000000..38dd9159229f
--- /dev/null
+++ b/media-video/gaupol/gaupol-1.15-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature virtualx xdg-utils
+
+DESCRIPTION="A subtitle editor for text-based subtitles"
+HOMEPAGE="https://otsaloma.io/gaupol/"
+SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	app-text/iso-codes
+	dev-python/charset-normalizer[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+"
+BDEPEND="
+	sys-devel/gettext
+	test? (
+		app-dicts/myspell-en
+		|| (
+			app-text/enchant[hunspell]
+			app-text/enchant[nuspell]
+		)
+		app-text/gspell[introspection]
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.md NEWS.md README.md README.aeidon.md )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.12-fix-prefix.patch"
+)
+
+python_test() {
+	virtx epytest
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+
+	# To check which GStreamer plugins are required (vaapisink is mentioned in the code but it is not used):
+	# plugins=$(qlist -e gaupol | xargs grep -ho 'Gst.ElementFactory.*' | cut -d'"' -f2 | sort -u | grep -vFx vaapisink)
+	# xargs -n1 gst-inspect-1.0 <<< "$plugins" | awk '/Filename/ {print $2}' | sort -u | xargs qfile
+	optfeature "integrated video player support" \
+		"media-libs/gstreamer[introspection] media-libs/gst-plugins-base[pango] media-plugins/gst-plugins-gtk"
+	optfeature "external video previewing support" "media-video/mpv" "media-video/mplayer" "media-video/vlc"
+
+	optfeature "spellchecking support" "app-text/gspell[introspection]"
+	# To list dictionaries supported by gaupol:
+	# python3 -c 'import aeidon; print(*aeidon.SpellChecker.list_languages(), sep="\n")'
+	optfeature "spellchecking with app-dicts/myspell-* dictionaries using the nuspell backend" \
+		"app-text/enchant[nuspell]"
+	optfeature "spellchecking with app-dicts/myspell-* dictionaries using the hunspell backend" \
+		"app-text/enchant[hunspell]"
+	optfeature "spellchecking with app-dicts/aspell-* dictionaries" \
+		"app-text/enchant[aspell]"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/media-video/gaupol/gaupol-1.15.ebuild b/media-video/gaupol/gaupol-1.15.ebuild
deleted file mode 100644
index de6253f7c5e9..000000000000
--- a/media-video/gaupol/gaupol-1.15.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit distutils-r1 virtualx xdg-utils
-
-DESCRIPTION="A subtitle editor for text-based subtitles"
-HOMEPAGE="https://otsaloma.io/gaupol/ https://github.com/otsaloma/gaupol/"
-SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="spell"
-
-RDEPEND="
-	app-text/iso-codes
-	dev-python/charset-normalizer[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[${PYTHON_USEDEP}]
-	x11-libs/gtk+:3[introspection]
-	spell? ( app-text/gspell[introspection] )
-"
-BDEPEND="
-	sys-devel/gettext
-	test? (
-		app-dicts/myspell-en
-		app-text/enchant[hunspell]
-		app-text/gspell[introspection]
-	)
-"
-
-distutils_enable_tests pytest
-
-DOCS=( AUTHORS.md NEWS.md README.md README.aeidon.md )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-1.12-fix-prefix.patch"
-)
-
-python_test() {
-	virtx epytest
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-	if [[ -z ${REPLACING_VERSIONS} ]]; then
-		elog "The integrated video player requires media-plugins/gst-plugins-gtk."
-		elog ""
-		elog "External video previewing support requires MPV, MPlayer or VLC."
-		if use spell; then
-			elog ""
-			elog "Spell-checking requires a dictionary, any of app-dicts/myspell-*"
-			elog "or app-text/aspell with the appropriate L10N variable."
-			elog ""
-			elog "Additionally, make sure that app-text/enchant has the correct flags enabled:"
-			elog "USE=hunspell for myspell dictionaries and USE=aspell for aspell dictionaries."
-		fi
-	fi
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_icon_cache_update
-}