net-libs/libnpupnp: [QA] use eautoreconf, fix DEPEND

- Use eautoreconf instead of autogen.sh (handles everything we need, plus
  inheriting autotools.eclass guarantees correct dependencies).
- Define DEPEND (these dependencies need to be around at build-time too)
- Add missing virtual/pkgconfig BDEPEND

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/net-libs/libnpupnp/libnpupnp-4.1.5-r1.ebuild b/net-libs/libnpupnp/libnpupnp-4.1.5-r1.ebuild
new file mode 100644
index 000000000000..e43e9d04e31f
--- /dev/null
+++ b/net-libs/libnpupnp/libnpupnp-4.1.5-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A C++ base UPnP library, derived from Portable UPnP, a.k.a libupnp"
+HOMEPAGE="https://framagit.org/medoc92/npupnp"
+SRC_URI="https://www.lesbonscomptes.com/upmpdcli/downloads/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/expat
+	net-libs/libmicrohttpd
+	net-misc/curl
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-client \
+		--enable-debug \
+		--enable-device \
+		--enable-gena \
+		--enable-ipv6 \
+		--enable-optssdp \
+		--enable-reuseaddr \
+		--enable-soap \
+		--enable-ssdp \
+		--enable-tools \
+		--enable-webserver
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}