net-misc/proxychains: version bump to 4.11

1 files changed, 47 insertions, 0 deletions

diff --git a/net-misc/proxychains/proxychains-4.11.ebuild b/net-misc/proxychains/proxychains-4.11.ebuild
new file mode 100644
index 000000000000..6de40d7302c1
--- /dev/null
+++ b/net-misc/proxychains/proxychains-4.11.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit toolchain-funcs eutils multilib
+
+MY_PN=${PN}-ng
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="force any tcp connections to flow through a proxy (or proxy chain)"
+HOMEPAGE="https://github.com/rofl0r/proxychains-ng/"
+SRC_URI="https://github.com/rofl0r/${MY_PN}/releases/download/v${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-4.10-makefile.patch
+	sed -i "s/^\(LDSO_SUFFIX\).*/\1 = so.${PV}/" Makefile || die
+	tc-export CC
+}
+
+src_configure() {
+	# not autotools
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--sysconfdir="${EPREFIX}"/etc \
+		|| die
+}
+
+src_install() {
+	dobin ${PN}
+	dodoc AUTHORS README TODO
+
+	dolib.so lib${PN}.so.${PV}
+	dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so.${PV:0:1}
+	dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so
+
+	insinto /etc
+	doins src/${PN}.conf
+}