net-misc/vmpsd: Port to EAPI 7

Closes: https://bugs.gentoo.org/739944
Closes: https://bugs.gentoo.org/740828
Package-Manager: Portage-3.0.7, Repoman-3.0.1
Signed-off-by: David Seifert <soap@gentoo.org>

2 files changed, 34 insertions, 15 deletions

diff --git a/net-misc/vmpsd/files/vmpsd-1.4-Wreturn-type.patch b/net-misc/vmpsd/files/vmpsd-1.4-Wreturn-type.patch
new file mode 100644
index 000000000000..e6354c902c12
--- /dev/null
+++ b/net-misc/vmpsd/files/vmpsd-1.4-Wreturn-type.patch
@@ -0,0 +1,11 @@
+--- a/data.c
++++ b/data.c
+@@ -35,7 +35,7 @@
+ 	exit(1);
+ }
+ 
+-void *xfree(void *p) {
++void xfree(void *p) {
+ 
+ 	if (p == NULL) return;
+ 	vmps_log(DEBUG|SYSTEM, "FREE: %x",p);
diff --git a/net-misc/vmpsd/vmpsd-1.4.ebuild b/net-misc/vmpsd/vmpsd-1.4.ebuild
index e2dd42654288..242eeee574a7 100644
--- a/net-misc/vmpsd/vmpsd-1.4.ebuild
+++ b/net-misc/vmpsd/vmpsd-1.4.ebuild
@@ -1,40 +1,48 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
-inherit eutils flag-o-matic autotools
+EAPI=7
+
+inherit autotools
 
 DESCRIPTION="An open-source VLAN management system"
 HOMEPAGE="http://vmps.sourceforge.net"
 SRC_URI="mirror://sourceforge/vmps/${P}.tar.gz"
+
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc ~x86"
-IUSE=""
-DEPEND="net-analyzer/net-snmp[ucd-compat(+)]
+
+RDEPEND="net-analyzer/net-snmp:=[ucd-compat(+)]"
+DEPEND="
+	${RDEPEND}
 	dev-libs/openssl"
-S=${WORKDIR}/${PN}
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4-snmp-support.patch
+	"${FILESDIR}"/${PN}-1.3-64bit.patch
+	"${FILESDIR}"/${PN}-1.4-Wreturn-type.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${PN}-1.4-snmp-support.patch
-	epatch "${FILESDIR}"/${PN}-1.3-64bit.patch
-	# Merged upstream
-	#EPATCH_OPTS="-d${S}" \
-	#epatch "${FILESDIR}"/${PN}-1.3-format-sec.patch
+	default
+	mv configure.{in,ac} || die
 	eautoreconf
 }
 
 src_configure() {
 	econf \
-		--sysconfdir=/etc/vmpsd \
+		--sysconfdir="${EPREFIX}"/etc/vmpsd \
 		--enable-snmp \
 		LIBS="-lssl"
 }
 
 src_install() {
-	emake DESTDIR="${D}" install
-	dodoc README INSTALL AUTHORS doc/*txt
+	default
+
+	dodoc doc/*txt external/simple tools/vqpcli.pl
 	newdoc external/README README.external
 	newdoc tools/README README.tools
-	dodoc external/simple tools/vqpcli.pl
 }