sci-astronomy/siril: add 1.2.3

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Signed-off-by: Jason Zaman <perfinion@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/sci-astronomy/siril/Manifest b/sci-astronomy/siril/Manifest
index 2840ba6a92d8..cb5cfbd03c0b 100644
--- a/sci-astronomy/siril/Manifest
+++ b/sci-astronomy/siril/Manifest
@@ -1,2 +1,3 @@
 DIST siril-1.2.0.tar.bz2 4500147 BLAKE2B 7ff4fa5bf1b578336c82bd0f67e404fe47715640edae9cb231da4a3c6a30638612e77515049d56dd1d444965ad58f12d5e2516ad13d3e726f13242b11d91b954 SHA512 7df7b17d65a2aad9e0edd4b5022c1d23688ad8884a973d2195391234151aff0824e155ce949b385a951eaef71065a811f33b54e08b865ab5fa6c1d331841663c
 DIST siril-1.2.1.tar.bz2 4596163 BLAKE2B c461a397e623164ccb2310b26aede120bf587b3491a2af3fab446af5ecbfb716169120b549c496bb615d3b7ac6175629258173fe66682ef4684ef5cf01d64761 SHA512 352b3e761a2d863d4ce4e01b0bf4181d8fefa903478973b50ace76ff419dbf07775099a994e685cd83cc2210b34ca10fb98004cedfdea34fe0c1520b4892bb6d
+DIST siril-1.2.3.tar.bz2 4615997 BLAKE2B f8464849fad03faca07f238b3abd08c59126dab567666d92f1a53d2cea302608fe40b5532c6544029e869c639d1fc625c8ccc98779e678457713675c43225a74 SHA512 52cfa86ce0ddede42a3572c3d422cccca72da02a6efe207231ec98de9d59cc48704edd35e8ae83e86318e6980ce80eca3b9dba639e93f8551355a1328156ed9a
diff --git a/sci-astronomy/siril/siril-1.2.3.ebuild b/sci-astronomy/siril/siril-1.2.3.ebuild
new file mode 100644
index 000000000000..8b3fc3865d24
--- /dev/null
+++ b/sci-astronomy/siril/siril-1.2.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature toolchain-funcs xdg
+
+DESCRIPTION="A free astronomical image processing software"
+HOMEPAGE="https://siril.org/"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/free-astro/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/free-astro/siril/-/archive/${PV/_/-}/${PN}-${PV/_/-}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+LICENSE="GPL-3+ Boost-1.0"
+SLOT="0"
+IUSE="curl exif ffmpeg heif jpeg libconfig openmp png raw tiff wcs"
+
+DEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=dev-libs/json-glib-1.2.6
+	media-libs/librtprocess
+	>=media-libs/opencv-4.4.0:=
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	x11-libs/gdk-pixbuf:2
+	x11-libs/cairo
+	x11-libs/pango
+	>=x11-libs/gtk+-3.20.0:3
+	curl? ( net-misc/curl )
+	exif? ( >=media-gfx/exiv2-0.25:= )
+	ffmpeg? ( media-video/ffmpeg:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	libconfig? ( >=dev-libs/libconfig-1.4:=[cxx] )
+	png? ( >=media-libs/libpng-1.6.0:= )
+	raw? ( media-libs/libraw:= )
+	tiff? ( media-libs/tiff:= )
+	wcs? ( >=sci-astronomy/wcslib-7.7:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="dev-build/cmake
+	x11-base/xorg-proto"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-docfiles.patch"
+	"${FILESDIR}/${PN}-1.2-fseek64-musl.patch"
+	"${FILESDIR}/${PN}-1.2.1-options.patch"
+)
+
+DOCS=( README.md NEWS ChangeLog AUTHORS )
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dffms2=false
+		-Dcriterion=false
+		$(meson_use exif exiv2)
+		$(meson_use ffmpeg)
+		$(meson_use heif libheif)
+		$(meson_use jpeg libjpeg)
+		$(meson_use libconfig)
+		$(meson_use openmp)
+		$(meson_use png libpng)
+		$(meson_use raw libraw)
+		$(meson_use tiff libtiff)
+		$(meson_use wcs wcslib)
+		$(usex curl -Denable-libcurl=yes -Denable-libcurl=no)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	optfeature "gnuplot support" sci-visualization/gnuplot
+}