proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 53 insertions, 0 deletions

diff --git a/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild b/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild
new file mode 100644
index 000000000000..76018815c9cd
--- /dev/null
+++ b/sci-chemistry/burrow-owl/burrow-owl-1.5.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools-utils virtualx
+
+DESCRIPTION="Visualize multidimensional nuclear magnetic resonance (NMR) spectra"
+HOMEPAGE="http://burrow-owl.sourceforge.net/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.gz
+	examples? ( mirror://sourceforge/${PN}/burrow-demos.tar )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples static-libs"
+
+RDEPEND="
+	dev-libs/g-wrap
+	dev-libs/glib:2
+	dev-scheme/guile[networking,regex]
+	dev-scheme/guile-cairo
+	dev-scheme/guile-gnome-platform
+	sci-libs/starparse
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	dev-util/indent
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with doc doxygen doxygen)
+	)
+	autotools-utils_src_configure
+}
+
+src_test () {
+	cd "${AUTOTOOLS_BUILD_DIR}" || die
+	virtualmake -C test-suite check
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${AUTOTOOLS_BUILD_DIR}/doc/api/html/." )
+	autotools-utils_src_install
+
+	use examples && \
+		insinto /usr/share/${PN} && \
+		doins -r "${WORKDIR}"/burrow-demos/*
+}