sci-libs/umfpack: update EAPI 7 -> 8

(In the version that isn't p.masked because the entire suitesparse
ecosystem cannot multilib after the version bump.)

Signed-off-by: Eli Schwartz <eschwartz93@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/sci-libs/umfpack/umfpack-5.7.9-r1.ebuild b/sci-libs/umfpack/umfpack-5.7.9-r1.ebuild
new file mode 100644
index 000000000000..ee68d7850d4e
--- /dev/null
+++ b/sci-libs/umfpack/umfpack-5.7.9-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool toolchain-funcs
+
+DESCRIPTION="Unsymmetric multifrontal sparse LU factorization library"
+HOMEPAGE="https://people.engr.tamu.edu/davis/suitesparse.html"
+SRC_URI="http://202.36.178.9/sage/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+IUSE="+cholmod doc"
+
+BDEPEND="virtual/pkgconfig
+	doc? ( virtual/latex-base )"
+DEPEND="
+	sci-libs/amd
+	>=sci-libs/suitesparseconfig-5.4.0
+	virtual/blas
+	cholmod? ( sci-libs/cholmod )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	econf \
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)" \
+		$(use_with doc) \
+		$(use_with cholmod)
+}
+
+src_compile() {
+	use doc && export VARTEXFONTS="${T}/fonts"
+	default
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}