sys-auth/keystone: bup

Package-Manager: portage-2.2.28

3 files changed, 171 insertions, 1 deletions

diff --git a/sys-auth/keystone/Manifest b/sys-auth/keystone/Manifest
index d756b6c5bd82..83bfd9ec703d 100644
--- a/sys-auth/keystone/Manifest
+++ b/sys-auth/keystone/Manifest
@@ -3,3 +3,4 @@ DIST keystone-8.1.0.tar.gz 1070643 SHA256 2a068686c3392215547c51579b6ffe782c6162
 DIST keystone-8.1.2.tar.gz 1073146 SHA256 9871dcef23774e28cef590514d162b21ef375b4ebb871e68b70bdd9231eb8e38 SHA512 e610ea2e3164d0f26eedf3c0b494d08b89023eb9579439793425d81e67e203ef2209192fb1d9028b6246b61069f580077184217ce5ef2745e2a28667e2675937 WHIRLPOOL 765f73ff0768498fdb67246a424dee8c8f2069fee709a3b0991000860e3802c1fde627cdbd2246198b60cc0b6069f5b061825a478ef886d85329f246431b6ccb
 DIST keystone-9.0.0.tar.gz 1181342 SHA256 ff8e14ef7880bcfdb83a81815f4686f5484d68ecac9dce48155403781643fa91 SHA512 08dbbb36f0cc22db8725797f75e88149777541a312484170cb2efb8f1cfe119ba385822f92674841745a41601d725db1f0b880710398ca69c3ad117b6e46607a WHIRLPOOL 4b8151b5fe8f5cbf0ab68a5dda806fe59b4739687cc0cf2a13b62f005a337dc94f725046d3edb49c62797921e369468f0675956c29761361824cea2275c029f4
 DIST keystone-9.0.2.tar.gz 1180101 SHA256 2420f3ac6dee1982708786827c676278976fc493f47e2d4a44421bc0f3f87a89 SHA512 40143897a716c7dd331593f43a488e17ef56a9bb8622e40ef9bbaaa739b44fab281ea2d598727de80c7820bd6e028074c0104b304a47d8f9df8ec38e635fd2a0 WHIRLPOOL dfdfcdcb0288413fcd6bc2566d427b06c7ffecfc53db7b717b36cd6df3d25a9f2562ee35051984456c438158026e877f8a9999c149e38a040c62594a9d78ad7c
+DIST keystone-9.1.0.tar.gz 1183959 SHA256 3828f8907d07901a3f0516b9ee99fbd42bd9d293e4fa137d850a46487c76bad3 SHA512 2326d3ef91e614df8c0cfc68c4c4ced5f28a9c2c07e7bf6b7e55078c12d00cbb910bb53e1aee9cfcded70cfd78ab250ae5316bfc40e79609e980f0512f308fc0 WHIRLPOOL 5f6fcdcd5e2bb6dd2f7a0feaf6645f06baa5cdcaa645dc18a6fc95d2eaddcc1d160d4735631c08a90103a392b502344e8d463b917fb78a286ac4dcc806f22029
diff --git a/sys-auth/keystone/keystone-2016.1.9999.ebuild b/sys-auth/keystone/keystone-2016.1.9999.ebuild
index 41da0d7961ee..4b1891d80d45 100644
--- a/sys-auth/keystone/keystone-2016.1.9999.ebuild
+++ b/sys-auth/keystone/keystone-2016.1.9999.ebuild
@@ -33,7 +33,9 @@ RDEPEND="
 	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
 	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
 	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	!~dev-python/routes-2.3.0[${PYTHON_USEDEP}]
 	>=dev-python/cryptography-1.0[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-1.3.0[${PYTHON_USEDEP}]
 	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
 	sqlite? (
 		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
@@ -55,10 +57,11 @@ RDEPEND="
 	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
 	!~dev-python/python-keystoneclient-1.8.0[${PYTHON_USEDEP}]
 	!~dev-python/python-keystoneclient-2.1.0[${PYTHON_USEDEP}]
+	<dev-python/python-keystoneclient-3.0.0[${PYTHON_USEDEP}]
 	>=dev-python/keystonemiddleware-4.0.0[${PYTHON_USEDEP}]
 	!~dev-python/keystonemiddleware-4.1.0[${PYTHON_USEDEP}]
 	>=dev-python/oslo-cache-1.5.0[${PYTHON_USEDEP}]
-	>=dev-python/oslo-concurrency-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.7.1[${PYTHON_USEDEP}]
 	>=dev-python/oslo-config-3.7.0[${PYTHON_USEDEP}]
 	>=dev-python/oslo-context-0.2.0[${PYTHON_USEDEP}]
 	>=dev-python/oslo-messaging-4.0.0[${PYTHON_USEDEP}]
diff --git a/sys-auth/keystone/keystone-9.1.0.ebuild b/sys-auth/keystone/keystone-9.1.0.ebuild
new file mode 100644
index 000000000000..1acfc54bf54f
--- /dev/null
+++ b/sys-auth/keystone/keystone-9.1.0.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 user
+
+DESCRIPTION="The Openstack authentication, authorization, and service catalog"
+HOMEPAGE="https://launchpad.net/keystone"
+SRC_URI="https://tarballs.openstack.org/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+sqlite ldap memcached mongo mysql postgres test"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+CDEPEND=">=dev-python/pbr-1.6[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	${CDEPEND}"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/webob-1.2.3-r1[${PYTHON_USEDEP}]
+	>=dev-python/eventlet-0.18.4[${PYTHON_USEDEP}]
+	>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/pastedeploy-1.5.0[${PYTHON_USEDEP}]
+	<=dev-python/paste-2.0.2[${PYTHON_USEDEP}]
+	>=dev-python/routes-1.12.3[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+	!~dev-python/routes-2.1[$(python_gen_usedep 'python2_7')]
+	!~dev-python/routes-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.0[${PYTHON_USEDEP}]
+	!~dev-python/cryptography-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	sqlite? (
+		>=dev-python/sqlalchemy-1.0.10[sqlite,${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[sqlite,${PYTHON_USEDEP}]
+	)
+	mysql? (
+		dev-python/mysql-python
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	postgres? (
+		dev-python/psycopg:2
+		>=dev-python/sqlalchemy-1.0.10[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.1.0[${PYTHON_USEDEP}]
+	)
+	>=dev-python/sqlalchemy-migrate-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.6[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-1.6.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-1.8.0[${PYTHON_USEDEP}]
+	!~dev-python/python-keystoneclient-2.1.0[${PYTHON_USEDEP}]
+	<dev-python/python-keystoneclient-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/keystonemiddleware-4.0.0[${PYTHON_USEDEP}]
+	!~dev-python/keystonemiddleware-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-cache-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.7.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-context-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-messaging-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-db-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-middleware-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-policy-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-service-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.5.0[${PYTHON_USEDEP}]
+	>=dev-python/oauthlib-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pysaml2-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/pysaml2-4.0.3[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.5.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/jsonschema-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/jsonschema-3.0.0[${PYTHON_USEDEP}]
+	~dev-python/pycadf-1.1.0[${PYTHON_USEDEP}]
+	!~dev-python/pycadf-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.4.0[${PYTHON_USEDEP}]
+	memcached? (
+		>=dev-python/python-memcached-1.48[${PYTHON_USEDEP}]
+		<=dev-python/python-memcached-1.57[${PYTHON_USEDEP}]
+	)
+	mongo? (
+		>=dev-python/pymongo-2.6.3[${PYTHON_USEDEP}]
+		<dev-python/pymongo-3.2[${PYTHON_USEDEP}]
+	)
+	ldap? (
+		>=dev-python/python-ldap-2.4[$(python_gen_usedep 'python2_7')]
+		<=dev-python/python-ldap-2.4.20[$(python_gen_usedep 'python2_7')]
+		~dev-python/ldappool-1.0[$(python_gen_usedep 'python2_7')]
+	)
+	|| (
+		www-servers/uwsgi[python,${PYTHON_USEDEP}]
+		www-apache/mod_wsgi[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)"
+
+#PATCHES=(
+#)
+
+pkg_setup() {
+	enewgroup keystone
+	enewuser keystone -1 -1 /var/lib/keystone keystone
+}
+
+python_prepare_all() {
+	# it's in git, but not in the tarball.....
+	sed -i '/^hacking/d' test-requirements.txt || die
+	mkdir -p ${PN}/tests/tmp/ || die
+	cp etc/keystone-paste.ini ${PN}/tests/tmp/ || die
+	sed -i 's|/usr/local|/usr|g' httpd/keystone-uwsgi-* || die
+	sed -i 's|python|python27|g' httpd/keystone-uwsgi-* || die
+	distutils-r1_python_prepare_all
+}
+
+# Ignore (naughty) test_.py files & 1 test that connect to the network
+#-I 'test_keystoneclient*' \
+python_test() {
+	nosetests -I 'test_keystoneclient*' \
+		-e test_static_translated_string_is_Message \
+		-e test_get_token_id_error_handling \
+		-e test_provider_token_expiration_validation \
+		-e test_import --process-restartworker --process-timeout=60 || die "testsuite failed under python2.7"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	diropts -m 0750
+	keepdir /etc/keystone /var/log/keystone
+	insinto /etc/keystone
+	insopts -m0640 -okeystone -gkeystone
+	doins etc/keystone.conf.sample etc/logging.conf.sample
+	doins etc/default_catalog.templates etc/policy.json
+	doins etc/policy.v3cloudsample.json etc/keystone-paste.ini
+	insinto /etc/keystone/httpd
+	doins httpd/*
+
+	fowners keystone:keystone /etc/keystone /etc/keystone/httpd /var/log/keystone
+}
+
+pkg_postinst() {
+	elog "You might want to run:"
+	elog "emerge --config =${CATEGORY}/${PF}"
+	elog "if this is a new install."
+	elog "If you have not already configured your openssl installation"
+	elog "please do it by modifying /etc/ssl/openssl.cnf"
+	elog "BEFORE issuing the configuration command."
+	elog "Otherwise default values will be used."
+}
+
+pkg_config() {
+	if [ ! -d "${ROOT}"/etc/keystone/ssl ] ; then
+		einfo "Press ENTER to configure the keystone PKI, or Control-C to abort now..."
+		read
+		"${ROOT}"/usr/bin/keystone-manage pki_setup --keystone-user keystone --keystone-group keystone
+	else
+		einfo "keystone PKI certificates directory already present, skipping configuration"
+	fi
+}