sys-boot/vboot-utils: version bump to 51_p20160427 (fixes bug 581470)

Package-Manager: portage-2.2.28

2 files changed, 84 insertions, 0 deletions

diff --git a/sys-boot/vboot-utils/Manifest b/sys-boot/vboot-utils/Manifest
index 56f89ed4a649..8b928635a0f1 100644
--- a/sys-boot/vboot-utils/Manifest
+++ b/sys-boot/vboot-utils/Manifest
@@ -1,2 +1,3 @@
 DIST vboot-utils-20130222gite6cf2c2-3.fc19.src.rpm 2170079 SHA256 f20235e5f708bcbe3b30cb684a5aa9fa3f60d1fdea454375db0e62bebabd0c41 SHA512 ccb5320f01d270ff30465e6ffc234d245220afdb9628f9b5f9e8abc7c91c5e58085b5e8eefe217e85faa18166576d945cad9f757d99927389473cb0a4337a05f WHIRLPOOL 9da1a4f503619c9754e4c0b1c2d52deb4c687e693ba521213e2406cba417f5b8ce5645285ed2e106c0d05f56bd325dc7f929692c5de2ff1be2bb7fe191f74c68
 DIST vboot-utils-42_p20150219.tar.xz 18578108 SHA256 058053fd48afeeb30b48c51eb932ee3f477b1e7fc429b56ed776262010f30226 SHA512 bf1b5579f80bfd3804d74f5fed5ca0f85ff3d66cc4efd1c5e744ab0de50309c7e5168fe9a751579e9fcc0cb7dda72fc98497b2e13437b357b0ad9bb063edd33a WHIRLPOOL 01e5ca949ef417930669783d02b03d103005c6daa395f46bb3eab96a8d7de06875e3017697ed42d6200ca8e649b6b21737c5fc773a25da6da7a61c268dceba90
+DIST vboot-utils-51_p20160427.tar.xz 18377808 SHA256 6fc03136474c7cfd88074a9ffe7880dc83917cc0a6be344df422e3f851b50146 SHA512 5b9af2815b8939ae21f4e430744902ccd811627d668eaba709354901eb70553e57050b9068b07fecdfec5bb2ece0c11f1cf0f1a01c0e5f886d1913e1478fe3d7 WHIRLPOOL 4aa9c506c77596b3b598293872ada9cfc127d02f5cf23248ebf131612dcff38058f28bd61d22fc516dfacd7ff9c97d656795cdcce0dd07471930bcc085061a47
diff --git a/sys-boot/vboot-utils/vboot-utils-51_p20160427.ebuild b/sys-boot/vboot-utils/vboot-utils-51_p20160427.ebuild
new file mode 100644
index 000000000000..803dbd37d47c
--- /dev/null
+++ b/sys-boot/vboot-utils/vboot-utils-51_p20160427.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+# This is the latest commit in the latest branch.
+GIT_SHA1="48b1a50b086e39332d2e1e51a73434e39c40b329"
+
+DESCRIPTION="Chrome OS verified boot tools"
+HOMEPAGE="https://chromium.googlesource.com/chromiumos/platform/vboot_reference/ http://dev.chromium.org/chromium-os/chromiumos-design-docs/verified-boot"
+# Can't use gitiles directly until b/19710536 is fixed.
+#SRC_URI="https://chromium.googlesource.com/chromiumos/platform/vboot_reference/+archive/${GIT_SHA1}.tar.gz -> ${P}.tar.gz"
+SRC_URI="mirror://gentoo/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~x86"
+IUSE="minimal static"
+
+LIB_DEPEND="dev-libs/openssl:0=[static-libs(+)]
+	sys-apps/util-linux:=[static-libs(+)]"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
+	!minimal? (
+		app-arch/xz-utils:=
+		dev-libs/libyaml:=
+	)"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )
+	app-crypt/trousers"
+
+S=${WORKDIR}
+
+src_prepare() {
+	sed -i \
+		-e 's: -Werror : :g' \
+		-e 's:${DESTDIR}/\(bin\|${LIBDIR}\):${DESTDIR}/usr/\1:g' \
+		-e 's:${DESTDIR}/default:${DESTDIR}/etc/default:g' \
+		Makefile || die
+}
+
+_emake() {
+	local arch=$(tc-arch)
+	emake \
+		V=1 \
+		QEMU_ARCH= \
+		ARCH=${arch} \
+		HOST_ARCH=${arch} \
+		LIBDIR="$(get_libdir)" \
+		DEBUG_FLAGS= \
+		MINIMAL=$(usev minimal) \
+		STATIC=$(usev static) \
+		$(usex elibc_musl HAVE_MUSL=1 "") \
+		"$@"
+}
+
+src_compile() {
+	tc-export CC AR CXX PKG_CONFIG
+	_emake TEST_BINS= all
+}
+
+src_test() {
+	_emake runtests
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+
+	insinto /usr/share/vboot/devkeys
+	doins tests/devkeys/*
+
+	insinto /usr/include/vboot
+	doins host/include/* \
+		firmware/include/gpt.h \
+		firmware/include/tlcl.h \
+		firmware/include/tss_constants.h
+
+	dolib.a build/libvboot_host.a
+
+	dodoc README
+}