x11-misc/j4-dmenu-desktop: make dmenu optional

Since x11-misc/j4-dmenu-desktop uses dmenu as default,
it's being installed as a dependency by default too.

But there are also pure wayland users, but dmenu can't be used on wayland.
As x11-misc/j4-dmenu-desktop is flexible, users can manually configure
a dmenu alternative, like dev-libs/bemenu.

The possibility of disabling dmenu also won't pull in any X11
dependencies from x11-misc/dmenu anymore.

Also migrated from cmake-utils to cmake.

Closes: https://bugs.gentoo.org/730740
Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.17-r1.ebuild b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.17-r1.ebuild
new file mode 100644
index 000000000000..8a8d8c7525b9
--- /dev/null
+++ b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-2.17-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_PV="r${PV}"
+
+DESCRIPTION="A fast desktop replacement for i3-dmenu-desktop"
+HOMEPAGE="https://github.com/enkore/j4-dmenu-desktop"
+SRC_URI="https://github.com/enkore/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="+dmenu test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-cpp/catch:1 )"
+RDEPEND="dmenu? ( x11-misc/dmenu )"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Respect users CFLAGS
+	sed -i -e "s/-pedantic -O2//" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_GIT_CATCH="no"
+		-DWITH_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	doman j4-dmenu-desktop.1
+}
+
+pkg_postinst() {
+	if ! use dmenu; then
+		elog "As you have disabled the 'dmenu' use flag,"
+		elog "x11-misc/dmenu won't be installed by default."
+		elog ""
+		elog "Since x11-misc/j4-dmenu-desktop uses x11-misc/dmenu as default,"
+		elog "you must configure your own replacement with --dmenu=<command>,"
+		elog "as otherwise it won't work."
+	fi
+}
diff --git a/x11-misc/j4-dmenu-desktop/metadata.xml b/x11-misc/j4-dmenu-desktop/metadata.xml
index 4e3a92938dfe..fd4200a47052 100644
--- a/x11-misc/j4-dmenu-desktop/metadata.xml
+++ b/x11-misc/j4-dmenu-desktop/metadata.xml
@@ -10,6 +10,9 @@
 		The purpose is to find .desktop files,
 		but shell commands can also be executed.
 	</longdescription>
+	<use>
+		<flag name="dmenu">Use <pkg>x11-misc/dmenu</pkg> as default. Disable to use a different implementation.</flag>
+	</use>	
 	<upstream>
 		<bugs-to>https://github.com/enkore/j4-dmenu-desktop/issues</bugs-to>
 		<remote-id type="github">enkore/j4-dmenu-desktop</remote-id>