1 files changed, 52 insertions, 0 deletions
diff --git a/app-misc/piper/piper-0.5.1.ebuild b/app-misc/piper/piper-0.5.1.ebuild
new file mode 100644
index 000000000000..33eae628b921
--- /dev/null
+++ b/app-misc/piper/piper-0.5.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit meson python-single-r1 udev
+
+DESCRIPTION="GTK configuration application for libratbag"
+HOMEPAGE="https://github.com/libratbag/piper"
+SRC_URI="https://github.com/libratbag/piper/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection
+	>=dev-libs/libratbag-0.13
+	gnome-base/librsvg[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/python-evdev[${PYTHON_MULTI_USEDEP}]
+	')
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libevdev
+	virtual/libudev
+"
+
+src_configure() {
+	python_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/
+}