1 files changed, 57 insertions, 0 deletions
diff --git a/media-libs/dav1d/dav1d-0.6.0-r1.ebuild b/media-libs/dav1d/dav1d-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..66afaa7d1510
--- /dev/null
+++ b/media-libs/dav1d/dav1d-0.6.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+SCM=""
+if [[ "${PV}" == "9999" ]]; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://code.videolan.org/videolan/dav1d"
+else
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+	SRC_URI="https://code.videolan.org/videolan/dav1d/-/archive/${PV}/${P}.tar.bz2"
+fi
+
+inherit ${SCM} meson ninja-utils multilib-minimal
+
+DESCRIPTION="dav1d is an AV1 Decoder :)"
+HOMEPAGE="https://code.videolan.org/videolan/dav1d"
+
+LICENSE="BSD-2"
+SLOT="0/4"
+IUSE="+8bit +10bit +asm"
+
+ASM_DEPEND=">=dev-lang/nasm-2.13.02"
+BDEPEND="asm? (
+		abi_x86_32? ( ${ASM_DEPEND} )
+		abi_x86_64? ( ${ASM_DEPEND} )
+	)"
+
+DOCS=( README.md doc/PATENTS THANKS.md )
+
+multilib_src_configure() {
+	local -a bits=()
+	use 8bit  && bits+=( 8 )
+	use 10bit && bits+=( 16 )
+
+	local enable_asm
+	if [[ ${MULTILIB_ABI_FLAG} == abi_x86_x32 ]]; then
+		enable_asm=false
+	else
+		enable_asm=$(usex asm true false)
+	fi
+
+	local emesonargs=(
+		-D bitdepths=$(IFS=,; echo "${bits[*]}")
+		-D enable_asm=${enable_asm}
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	eninja
+}
+
+multilib_src_install() {
+	DESTDIR="${D}" eninja install
+}