blob: 589730579a7232488e4991dc39e7087b24a968f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 2010-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
PYTHON_COMPAT=( python3_{9..10} )
inherit cmake python-any-r1
if [[ "${PV}" == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/BYVoid/OpenCC"
fi
DESCRIPTION="Library for conversion between Traditional and Simplified Chinese characters"
HOMEPAGE="https://github.com/BYVoid/OpenCC"
if [[ "${PV}" == "9999" ]]; then
SRC_URI=""
else
SRC_URI="https://github.com/BYVoid/OpenCC/archive/ver.${PV}.tar.gz -> ${P}.tar.gz"
fi
LICENSE="Apache-2.0"
SLOT="0/1.1"
KEYWORDS=""
IUSE="doc test"
RESTRICT="!test? ( test )"
BDEPEND="${PYTHON_DEPS}
doc? ( app-doc/doxygen )"
DEPEND="dev-cpp/tclap
dev-libs/darts
dev-libs/marisa:0=
dev-libs/rapidjson
test? (
dev-cpp/gtest
!hppa? ( !sparc? ( dev-cpp/benchmark ) )
)"
RDEPEND="dev-libs/marisa:0="
if [[ "${PV}" != "9999" ]]; then
S="${WORKDIR}/OpenCC-ver.${PV}"
fi
DOCS=(AUTHORS NEWS.md README.md)
src_prepare() {
rm -r deps || die
cmake_src_prepare
sed -e "s:\${DIR_SHARE_OPENCC}/doc:share/doc/${PF}:" -i doc/CMakeLists.txt || die
}
src_configure() {
local mycmakeargs=(
-DBUILD_DOCUMENTATION=$(usex doc ON OFF)
-DENABLE_BENCHMARK=$(if use test && has_version -d dev-cpp/benchmark; then echo ON; else echo OFF; fi)
-DENABLE_GTEST=$(usex test ON OFF)
-DUSE_SYSTEM_DARTS=ON
-DUSE_SYSTEM_GOOGLE_BENCHMARK=ON
-DUSE_SYSTEM_GTEST=ON
-DUSE_SYSTEM_MARISA=ON
-DUSE_SYSTEM_RAPIDJSON=ON
-DUSE_SYSTEM_TCLAP=ON
)
cmake_src_configure
}
|
GitWeb
