blob: c381cb981dfcc8e9fe9f15e51b47bcfc576bb922 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 flag-o-matic
MY_PN=pyOpenSSL
MY_P=${MY_PN}-${PV}
DESCRIPTION="Python interface to the OpenSSL library"
HOMEPAGE="
http://pyopenssl.sourceforge.net/
https://launchpad.net/pyopenssl
https://pypi.python.org/pypi/pyOpenSSL
"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
IUSE="doc examples"
RDEPEND="
>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
>=dev-python/cryptography-0.7[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
S=${WORKDIR}/${MY_P}
python_prepare_all() {
# https://github.com/pyca/pyopenssl/issues/41
sed -e "s/test_digest/_&/" -i OpenSSL/test/test_crypto.py
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C doc html
}
python_test() {
esetup.py test
# https://bugs.launchpad.net/pyopenssl/+bug/1237953
rm -rf tmp* *.key *.pem || die
}
python_install_all() {
use doc && local HTML_DOCS=( doc/_build/html/. )
use examples && local EXAMPLES=( examples/. )
distutils-r1_python_install_all
}
|
GitWeb
