blob: 771e3b3bd59198f61ef77ca3aded2d3f49d37b53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby31 ruby32 ruby33"
RUBY_FAKEGEM_RECIPE_DOC="none"
RUBY_FAKEGEM_EXTRADOC="README.rdoc README.ja.rdoc TODO ChangeLog"
RUBY_FAKEGEM_GEMSPEC="racc.gemspec"
RUBY_FAKEGEM_EXTENSIONS=(ext/racc/cparse/extconf.rb)
RUBY_FAKEGEM_EXTENSION_LIBDIR="lib/racc/cparse"
inherit ruby-fakegem
DESCRIPTION="A LALR(1) parser generator for Ruby"
HOMEPAGE="https://github.com/ruby/racc"
SRC_URI="https://github.com/ruby/racc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="doc test"
ruby_add_rdepend "virtual/ruby-ssl"
ruby_add_bdepend "dev-ruby/rake
test? ( dev-ruby/minitest dev-ruby/test-unit-ruby-core )"
all_ruby_prepare() {
sed -i -e 's/, :isolate//' Rakefile || die
sed -e '/bundler/ s:^:#:' \
-e '/require.*rdoc/ s:^:#:' \
-e '/RDoc/,/^end/ s:^:#:' \
-i Rakefile || die
# Avoid depending on rake-compiler since we don't use it to compile
# the extension.
sed -i -e '/rake-compiler/ s:^:#:' -e '/require.*extensiontask/ s:^:#:' Rakefile || die
sed -i -e '/ExtensionTask/,/^ end/ s:^:#:' Rakefile || die
# ...which means we need to generate the parser file here
for ruby in $(ruby_get_use_implementations) ; do
if has_version -b "virtual/rubygems[ruby_targets_${ruby}(-)]" &&
has_version -b "dev-ruby/rake[ruby_targets_${ruby}(-)]" ; then
${ruby} -S rake lib/racc/parser-text.rb || die
break
fi
done
sed -i -e 's:_relative ": "./:' ${RUBY_FAKEGEM_GEMSPEC} || die
}
all_ruby_install() {
all_fakegem_install
dodoc -r doc
docinto examples
dodoc -r sample
}
|
GitWeb
