blob: a11cb13d5052dba8228302dce25d724c7c0e74a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_ECLASS=cmake
inherit cmake-multilib
if [[ ${PV} == *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://aomedia.googlesource.com/aom"
else
SRC_URI="https://dev.gentoo.org/~lu_zero/${PN}/${P}.tar.gz"
S="${WORKDIR}"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~sparc x86"
fi
DESCRIPTION="Alliance for Open Media AV1 Codec SDK"
HOMEPAGE="https://aomedia.org"
LICENSE="BSD-2"
SLOT="0/2"
IUSE="doc examples"
IUSE="${IUSE} cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3"
IUSE="${IUSE} cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 cpu_flags_x86_avx cpu_flags_x86_avx2"
IUSE="${IUSE} cpu_flags_arm_neon"
REQUIRED_USE="
cpu_flags_x86_sse2? ( cpu_flags_x86_mmx )
cpu_flags_x86_ssse3? ( cpu_flags_x86_sse2 )
"
BDEPEND="abi_x86_32? ( dev-lang/yasm )
abi_x86_64? ( dev-lang/yasm )
abi_x86_x32? ( dev-lang/yasm )
x86-fbsd? ( dev-lang/yasm )
amd64-fbsd? ( dev-lang/yasm )
doc? ( app-doc/doxygen )
"
# the PATENTS file is required to be distributed with this package bug #682214
DOCS=( PATENTS )
multilib_src_configure() {
local mycmakeargs=(
-DENABLE_DOCS=$(multilib_native_usex doc ON OFF)
-DENABLE_EXAMPLES=$(multilib_native_usex examples ON OFF)
-DENABLE_NASM=OFF
-DENABLE_TESTS=OFF
-DENABLE_TOOLS=ON
-DENABLE_WERROR=OFF
# neon support is assumed to be always enabled on arm64
-DENABLE_NEON=$(usex cpu_flags_arm_neon ON $(usex arm64 ON OFF))
# ENABLE_DSPR2 / ENABLE_MSA for mips
-DENABLE_MMX=$(usex cpu_flags_x86_mmx ON OFF)
-DENABLE_SSE=$(usex cpu_flags_x86_sse ON OFF)
-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)
-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)
-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)
-DENABLE_SSE4_1=$(usex cpu_flags_x86_sse4_1 ON OFF)
-DENABLE_SSE4_2=$(usex cpu_flags_x86_sse4_2 ON OFF)
-DENABLE_AVX=$(usex cpu_flags_x86_avx ON OFF)
-DENABLE_AVX2=$(usex cpu_flags_x86_avx2 ON OFF)
)
cmake_src_configure
}
multilib_src_install() {
if multilib_is_native_abi && use doc ; then
local HTML_DOCS=( "${BUILD_DIR}"/docs/html/. )
fi
cmake_src_install
}
multilib_src_install_all() {
find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
}
|
GitWeb